循环工作表时，运行时错误6溢出

Question

I am using the code below to remove paths in Excel referencing add-ins for files shared by users. It works with some files, but using it with a new file and receiving a Runtime error 6 overflow error upon opening. It is stopping on the Cell Replace line.

Private Sub Workbook_Open()
    Dim i As Long
    Dim strWorksheetName As String

    strWorksheetName = ActiveSheet.Name

    Application.DisplayAlerts = False
    For i = 1 To Sheets.Count
        Sheets(i).Activate
        If Sheets(i).Type = xlWorksheet Then
            Cells.Replace What:="'c:\*xla*'!", Replacement:="", LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False
        End If
    Next i
    Application.DisplayAlerts = True

    Sheets(strWorksheetName).Activate

End Sub

Answer 1

This may be being caused because the Workbook_Open event is firing too soon, before everything is loaded.

You might have better luck if you don't try to Activate the worksheets. (Activating them would cause Excel to have to display them, which it might not be able to do because it is still doing other stuff. But making the changes without forcing the sheets to be displayed may let it continue doing what it wants to do. I'm guessing, but until someone comes up with another solution, a guess is as good as anything!)

Try changing your code to:

Private Sub Workbook_Open()
    Dim ws As Worksheet

    Application.DisplayAlerts = False
    For Each ws in Worksheets
        ws.Cells.Replace What:="'c:\*xla*'!", _
                         Replacement:="", _
                         LookAt:=xlPart, _
                         SearchOrder:=xlByRows, _
                         MatchCase:=False, _
                         SearchFormat:=False, _
                         ReplaceFormat:=False
    Next
    Application.DisplayAlerts = True

End Sub

If it works, I'll leave the answer here. If it doesn't, I'll delete the answer and someone else can make a suggestion.

Answer 2

It is possible that one or more 'sheets' is/are not .Visible . You cannot .Activate a 'sheet' if it the .Visible property is False or xlVeryHidden.

Option Explicit

Private Sub Workbook_Open()
    Dim i As Long

    Application.DisplayAlerts = False

    For i = 1 To Worksheets.Count
        With Worksheets(i)
            .Cells.Replace What:="'c:\*xla*'!", _
                           Replacement:=vbNullString, _
                           LookAt:=xlPart, _
                           SearchOrder:=xlByRows, _
                           MatchCase:=False, _
                           SearchFormat:=False, _
                           ReplaceFormat:=False
        End With
    Next i

End Sub

• Application.DisplayAlerts returns to the default of True after exiting the procedure that changed it to False.
• You don't need to .Activate ¹ a Worksheet in order to work on it and you can work on a hidden worksheet. Use a With ... End With statement to provide a wide parent worksheet hierarchy.
• If you don't activate another worksheet, you don't have to store and reactivate the original.
• If you work with the Worksheets collection rather than the Sheets collection then you don't have to check to see if the 'sheet' is a worksheet.

---

¹ _{See How to avoid using Select in Excel VBA macros for more methods on getting away from relying on select and activate to accomplish your goals.}