Delphi中的文件搜索忽略了一些Windows目录

Question

I'm using this code from this thread ( How to Search a File through all the SubDirectories in Delphi ) to find files recursively:

procedure FindFilePattern(root:String;pattern:String);
var
  SR:TSearchRec;
begin
  root:=IncludeTrailingPathDelimiter(root);
  if FindFirst(root+'*.*',faAnyFile,SR) = 0 then
  begin
      repeat
          Application.ProcessMessages;
          if ((SR.Attr and faDirectory) = SR.Attr ) and (pos('.',SR.Name)=0) then
             FindFilePattern(root+SR.Name,pattern)
          else
          begin
           if pos(pattern,SR.Name)>0 then Form1.ListBox1.Items.Add(Root+SR.Name);
          end;
      until FindNext(SR)<>0;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FindFilePattern('C:\','.exe');
end;

It's working but for some reason it's ignoring the directories Program Files, Program Files (x86) and Users. Unfortunatelly, the files I'm searching are in those folders. Does anybody know why it's happening?

Any tip will be very helpful,

Thanks

Answer 1

Like Jerry Dodge mentioned, security rights is certainly one thing you might need to account for. Your code may need to be run as an admin in order to access various system directories, and directories belonging to other users. For the most part, simply enumerating the directories you have mentioned does not require elevated rights. But if you find that you encounter directories that do, you can either:

1. add a UAC manifest to your app that requests elevation

2. move your enumeration code into a separate process or COM object that you can then run elevated from an un-elevated process when needed.

But aside from that, the FindFilePattern() procedure you copied is also implemented wrong to begin with. It is:

1. comparing file attributes incorrectly. The expression (SR.Attr and faDirectory) = SR.Attr ) will be true if the entry is a file, or is a directory with NO ATTRIBUTES on it. It is not uncommon to encounter directories with attributes, such as system, compressed, indexed, etc.

2. comparing file names incorrectly. The expression (pos('.',SR.Name)=0) will be true for all files and directories that do not contain a . character at all. Almost all files have a . , and even directories can have a . as well. When handling directories, you need to ignore only the special . and .. directory entries specifically, not any entry that has a . in it.

3. Worse, the combination of #1 and #2 acting together is allowing directories that have attributes, and directories that contain . , to be treated as files instead of as directories. The code is not handling directories correctly in general, let alone recursively.

4. leaking all of the search handles. FindClose() must be called if FindFirst() is successful, regardless of FindNext() .

Try something more like this instead:

uses
  SysUtils, Masks;

procedure FindFilePattern(root: String; pattern: String);
var
  SR: TSearchRec;
begin
  root := IncludeTrailingPathDelimiter(root);
  if FindFirst(root + '*.*', faAnyFile, SR) = 0 then
  try
    repeat
      Application.ProcessMessages;
      if (SR.Attr and faDirectory) <> 0 then
      begin
        if (SR.Name <> '.') and (Sr.Name <> '..') then
          FindFilePattern(root + SR.Name, pattern);
      end else
      begin
        if MatchesMask(SR.Name, pattern) then
          Form1.ListBox1.Items.Add(Root + SR.Name);
      end;
    until FindNext(SR) <> 0;
  finally
    FindClose(SR);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FindFilePattern('C:\', '*.exe');
end;

Answer 2

Your application needs to be running with elevated privileges in order for it to access some subdirectories within the ones you speak of. As a temporary test, run "As Administrator" to verify this. If this is indeed your case, then you should add a manifest to require elevation upon startup.

Later versions of Delphi have this built-in. Under Project Options, go to the "Application" page, and check "Enable Administrator Privileges". Of course, this is the quick and easy way with the IDE, and you should instead consider writing your own custom manifest, especially if you're running an older version of Delphi which doesn't have this option.