Excel VBA导出到Access：ADO错误

Question

I am trying to export a worksheet to Access where it will be paste appended into an existing table. I've referenced this post , this other post , and this other post . I'm getting an error that was not addressed in any of them that I think might be related to VBA libraries but could be something completely different. Here is my code:

Sub ExcelToAccessAdo()

Dim cn As ADODB.Connection, rs As ADODB.Recordset, row As Long
Set cn = New ADODB.Connection
cn.Open "Provider=Microsoft.ACE.OLEDB.12.0; " & _
        "Data Source=filepath\AccessDB.accdb;" 'this is a different filepath from the real one.

' open a recordset
Set rs = New ADODB.Recordset
rs.Open "Table Export", cn, adOpenKeyset, adLockOptimistic, adCmdTable

row = 2    ' the start row in the worksheet
Do While Not IsEmpty(Worksheets("Table Export").Range("A" & row))

    With rs
        .AddNew    ' create a new record
        .Fields("REPTNO") = Worksheets("Table Export").Range("A" & row).Value
        .Update
    End With
    row = row + 1
Loop

rs.Close
Set rs = Nothing
cn.Close
Set cn = Nothing

End Sub

The worksheet name and Access table name are the same. Also the .Fields("REPTNO") line is straight from the other person's post so I don't know if I'll have to change it or not.

The error is Run-time error '-2147217900 (80040e14)': Syntax error in FROM clause.

on the line rs.Open "Table Export", cn, adOpenKeyset, adLockOptimistic, adCmdTable .

This is a strange error since it seems like an error I'd get when running SQL, but I'm assuming there's some background SQL happening with an INSERT INTO clause. Which maybe this is some type of file path issue with Excel? Any help?

Here are my library References:

• Microsoft Excel 14.0 Object Library
• OLE Automation
• Microsoft Office 14.0 Object Library
• Microsoft Forms 2.0 Object Library
• Microsoft ActiveX Data Objects 6.1 Library
• Microsoft ActiveX Data Objects Recordset 6.0 Library

Answer 1

感谢@JNevill指出我只需要使用方括号：

rs.Open "[Table Export]", cn, adOpenKeyset, adLockOptimistic, adCmdTable

Answer 2

Try to stay away from spaces in any object name (Tables, Field_Names, Forms, Reports, etc.). You can do this, but as you can tell, it's going to cause more time and unnecessary frustration to normalize things. Also, don't use reserved words in your code.

https://support.microsoft.com/en-us/kb/286335