使用ADO命令在SQL Server中运行存储过程时如何解决“多站OLE DB操作…”错误

Question

I'm trying to run a SQL Server stored procedure that returns records using an ADO Command object. I'm able to connect to the database (my connection is used elsewhere in my code and, when tested in the following function, the state property returns 1 -- connected) but get the following error at the point where the command is executed.

Run-time error '-2147217887 (80040e21)':
Multiple-stop OLE DB operation generated errors. Check each OLD DB status value, if available. No work was done.

From what I've read online, it may be something to do with the parameter, but I can't see anything wrong with it (I've added a watch and inspected each item in the params collection in debug mode).

Here's the function that is intended to return the stored procedure results in an ADODB Recordset:

Public Function GetRecordset(CmdType As String, CmdText As String, Optional InputParams As Collection) As ADODB.Recordset

        Dim prm As ADODB.Parameter

        Select Case CmdType
            Case "proc"
                If cmd Is Nothing Then

                    Set cmd = New ADODB.Command

                    With cmd
                        Set .ActiveConnection = GetConnection

                        For Each prm In InputParams
                            .Parameters.Append prm
                        Next prm

                        Select Case CmdType
                            Case "proc": .CommandType = adCmdStoredProc
                            Case "sql": .CommandType = adCmdText
                        End Select

                        .CommandText = CmdText
                        Set rs = .Execute
                    End With

                    Set GetRecordset = rs

                End If

            Case "sql"

        End Select
End Function

As above, the error occurs on the line:

Set rs = .Execute

The expected input parameter in the stored procedure is of type numeric(6,0). The parameter passed to the function is as follows:

prm.Direction = adParamInput
prm.Name = "@ISOWk"
prm.NumericScale = 6
prm.Precision = 0
prm.Type = adNumeric
prm.Value = 201613

I'm able to execute the stored procedure directly in SSMS so I am confident that it is not the issue here.

Any suggestions welcome.

Thanks

Answer 1

You have your .Precision and .Scale backwards:

prm.NumericScale = 6
prm.Precision = 0

A value with a precision of 0 can store 0 digits. If the data-type is NUMERIC(6, 0) the parameter should be:

prm.NumericScale = 0
prm.Precision = 6

Precision is the number on the left.