在循环vba excel上调用sub时更新字符串

Question

Bonjour!

I have a loop on my project, and within the loop I call a sub (Stcount) to count the column number of an element. This sub feeds on a string (ststring) that changes with each loop. However, the sub (Stcount), does not appear to recognize the change in the string (ststring).

First, I start by defining some variables I will use for this sequences

Public counterSt As Integer
Public ststring As String
Public rng As Range
Public rng2 As Range

In this sub, I define the strings that will be the basis for my sub

Sub test()

Dim Stx(9) As String
    Stx(1) = "Stx1"
    Stx(2) = "Stx2"
    Stx(3) = "Stx3"
    Stx(4) = "Stx4"
    Stx(5) = "Stx5"
    Stx(6) = "Stx6"
    Stx(7) = "Stx7"
    Stx(8) = "Stx9"
    Stx(9) = "Stx10"

Set rng2 = Range("G10")
For i = 1 To 9
    ststring = "ist_" & Stx(i)
    Call StCount
    rng2.Value = counterSt
    Set rng2 = rng2.Offset(1, 0)

Next i

End Sub

When I call StCount, it will update the value for counterSt. For the first string, it works fine. But when it loops, it does not seem to recognize there is a new string that it should use (ststring). And thus, it returns the same value each time!

Sub StCount()
Set rep = ActiveWorkbook.Sheets("Sheet2")
Set sh1 = ActiveWorkbook.Sheets("Sheet1")


    Dim trng As Range
    Set trng = rep.Range("A4:HV4")

    For Each rng In trng
        If rng.Value = ststring Then
        counterSt = Range(rng, rng.End(xlToLeft)).Columns.count
        End If
    Next rng
End Sub

As check, I tried to see if Ststring was updated correctly (it was). I also tried to update the value of ststring manually and call StCount different times in the same sub with different ststrings (it also worked). Thus, I believe the problem is with the loop.

Ideas?

Answer 1

Your code works fine for me but I don't see any need for public variables. I'd suggest something more like this:

Sub test()
    Dim rng2                  As Range
    Dim i                     As Long
    Dim Stx(9)                As String

    Stx(1) = "Stx1"
    Stx(2) = "Stx2"
    Stx(3) = "Stx3"
    Stx(4) = "Stx4"
    Stx(5) = "Stx5"
    Stx(6) = "Stx6"
    Stx(7) = "Stx7"
    Stx(8) = "Stx9"
    Stx(9) = "Stx10"

    Set rng2 = Range("G10")
    For i = 1 To 9
        rng2.Value = StCount("ist_" & Stx(i))
        Set rng2 = rng2.Offset(1, 0)

    Next i

End Sub
Function StCount(sTest As String)
    Dim rng                   As Range
    Dim trng                  As Range
    Dim rep                   As Worksheet
    Dim sh1                   As Worksheet
    Set rep = ActiveWorkbook.Sheets("Sheet2")
    Set sh1 = ActiveWorkbook.Sheets("Sheet1")


    Set trng = rep.Range("A4:HV4")

    For Each rng In trng
        If rng.Value = sTest Then
            StCount = Range(rng, rng.End(xlToLeft)).Columns.Count
            Exit For
        End If
    Next rng
End Function