ASP Classic电子邮件'80040213'传输无法连接到服务器

Question

I know there are plenty of questions out there with this but none seem to have an answer which works for me.

My application is ASP Classic, the server it is running on is Windows Server 2000 (very old I know), I am using an Office365 server and I'm using the information provided by the Office365 when I login to the email (Port 587, correct username and password, correct smtp server, TLS set to true).

I always get "CDO.Message.1 error '80040213' The transport failed to connect to the server." as an error message, the line it errors on is the .Send command.

    Const cdoSendUsingMethod           = "http://schemas.microsoft.com/cdo/configuration/sendusing"
    Const cdoSendUsingPort             = 2
    Const cdoSMTPServer                = "http://schemas.microsoft.com/cdo/configuration/smtpserver"
    Const cdoSMTPServerPort            = "http://schemas.microsoft.com/cdo/configuration/smtpserverport"
    Const cdoSMTPConnectionTimeout     = "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"
    Const cdoSMTPAuthenticate          = "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"
    Const cdoBasic                     = 1
    Const cdoSendUserName              = "http://schemas.microsoft.com/cdo/configuration/sendusername"
    Const cdoSendPassword              = "http://schemas.microsoft.com/cdo/configuration/sendpassword"
    'Use SSL for the connection (False or True)
    Const cdoSendTLS                   = "http://schemas.microsoft.com/cdo/configuration/smtpusessl"

    ' create CDOSYS objects
    Set objCDOSYSMail = Server.CreateObject("CDO.Message")
    Set objCDOSYSCon = Server.CreateObject ("CDO.Configuration")

    'Set our smtp server
    objCDOSYSCon.Fields.Item(cdoSMTPServer) = "smtp.office365.com"
    objCDOSYSCon.Fields.Item(cdoSMTPAuthenticate) = cdoBasic
    objCDOSYSCon.Fields.Item(cdoSendUserName) = "my.email@email.com"
    objCDOSYSCon.Fields.Item(cdoSendPassword) = "password"
    'objCDOSYSCon.Fields.Item(cdoSMTPServerPort) = 587
    objCDOSYSCon.Fields.Item(cdoSendUsingMethod) = cdoSendUsingPort
    objCDOSYSCon.Fields.Item(cdoSendTLS) = True
    objCDOSYSCon.Fields.Item(cdoSMTPConnectionTimeout) = 30

    objCDOSYSCon.Fields.Update

    'Use our new configurations for our mailer
    Set objCDOSYSMail.Configuration = objCDOSYSCon

    strSpecFile = Application("px683_network_downloads_specs") & strSpecFileName

    objCDOSYSMail.From = "to.email@email.com"
    objCDOSYSMail.To = "my.email@email.com"
    objCDOSYSMail.Subject = "A subject"
    objCDOSYSMail.HTMLBody = "Some text for the body"

    'Normal level of importance
    objCDOSYSMail.Send

    set objCDOSYSMail = nothing
    set objCDOSYSCon = nothing

I have tried with port 25 without any luck as well. If I use another email service which doesn't use SSL at all (local service, not Office365) I have no issue (I comment out usessl and change the port to 25). Additionally if I try to use a different email service which I have running flawlessly in an ASP.Net application I get the same issues, this other email service uses port 25 and SSL and is not an Office365 service.

Answer 1

I have had this issue before. Basically you're not being authenticated to use the mail transport on the server.

Either your SMTP server isn't allowed to send outbound mail (eg to stop mail relay), you're username and password are incorrect or the port you are using needs a higher security level to send the mail. In the later instance it could be that Office365 requires SSL auth...maybe worth looking there.

If all else fails you can try using a 3rd party provider. We use SendInBlue on their £4.35 package. You're allowed to send up to 40,000 emails through their system. We found that sending the mail to a 3rd party totally removes issues over server settings stopping the mail transport function. We use this for both Classic ASP and PHP sites now.

Hope that helps.

Answer 2

With Office 365 and CDO you have to use port 25, even if you're using authenication. Looking at your code I think the port is the only thing to change, but here's a tried and tested configuration.

Set iConfg = Server.CreateObject("CDO.Configuration")
Set Flds = iConfg.Fields
With Flds
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "smtp.office365.com"
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = true
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "myaccount@mydomain.com"
        .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "mypassword"
        .Update
End With
objMail.Configuration = iConfg

Answer 3

I was finally able to get this working by moving the application to a Windows Server 2012 machine. I had to jump through a couple of loops which come with moving something that old between servers but I was able to get it working.

I was only able to use Port 25, 587 doesn't work. Keep in mind I tried port 25 on the original server and that didn't work there either.