检查文本或＃是否在单元格中，如果并且仅存在，则添加该单元格和静态文本

Question

Ok, so I'm doing mail merges for html email templates. I have these things so close to being 100% but I just need to do the following:

I need to insert editors and their affiliation like this: John doe (USA), Jane doe (Africa) and Frank doe (Canada)

The first and last names are in column A, C, and E. The affiliations are in B, D, and F.

How can I set myself up in Excel to add the parenthesis IF there is a second or third editor. And how can I make the "and" be inserted when there is only two or three editors where it needs to go?

Answer 1

I will post the formula here and explain a simple method for how I work though these as it might help you in the future.

For these replicating type formula where it is just going to check the same thing again and again I find it easiest to get it working for the first couple of components then applying that logic.

So for the first name I make the assumption there will always be at least one name there and do the formatting formula in a cell.

=S2 & " (" &AB2&")"

Then I do the conditional formatting of the second name in the cell to the right of it (in this case). This time I test to see if both the name and affiliation are populated and if they are the name is displayed and formatted else nothing is displayed.

=IF(AND(T2>"",AC2>""),T2&" ("&AC2&")","")

This formula can then be copied across so it applies to all the names/affiliations columns.

Next I move on to the comma/and test, this just checks if there are one or two additional items and if there are two display a comma but if only one display 'and'.

=IF(AND(T2>"",AC2>"",U2>"",AD2>""),", "," and "))

This is again copied across to cover all the columns required. The only difference is the last column where it is either empty or 'and' depending if it is populated.

All you have to do to get everything going is, basically, concatenate the formula together via copy and paste into a single cell or by chaining cell references.

This isn't particularly pretty or efficient but it works, is simple once you get the hang of it and doesn't require VBA.

Complete formula.

=S2 & " (" &AB2&")"&IF(OR(T2="",AC2=""),"",IF(AND(T2>"",AC2>"",U2>"",AD2>""),", "," and "))&IF(AND(T2>"",AC2>""),T2&" ("&AC2&")","")&IF(OR(U2="",AD2=""),"",IF(AND(U2>"",AD2>"",V2>"",AE2>""),", "," and "))&IF(AND(U2>"",AD2>""),U2&" ("&AD2&")","")&IF(OR(V2="",AE2=""),"",IF(AND(V2>"",AE2>"",W2>"",AF2>""),", "," and "))&IF(AND(V2>"",AE2>""),V2&" ("&AE2&")","")&IF(OR(W2="",AF2=""),"",IF(AND(W2>"",AF2>"",X2>"",AG2>""),", "," and "))&IF(AND(W2>"",AF2>""),W2&" ("&AF2&")","")&IF(OR(X2="",AG2=""),"",IF(AND(X2>"",AG2>"",Y2>"",AH2>""),", "," and "))&IF(AND(X2>"",AG2>""),X2&" ("&AG2&")","")&IF(OR(Y2="",AH2=""),"",IF(AND(Y2>"",AH2>"",Z2>"",AI2>""),", "," and "))&IF(AND(Y2>"",AH2>""),Y2&" ("&AH2&")","")&IF(OR(Z2="",AI2=""),"",IF(AND(Z2>"",AI2>"",AA2>"",AJ2>""),", "," and "))&IF(AND(Z2>"",AI2>""),Z2&" ("&AI2&")","")&IF(OR(AA2="",AJ2=""),""," and ")&IF(AND(AA2>"",AJ2>""),AA2&" ("&AJ2&")","")