Excel-通过随机单元格中的字符串引用另一个工作表，并引用其给定行中的值

Question

I'm trying to reference a string in another worksheet in a random cell, and reference a value in its given row.

The reason is that I'm working with 30+ documents, and the given string (and the value that I need next to it) Appears at different positions in each document.

I need to collect these values from each document, and combine it into one.

Thanks!

Answer 1

Say on Sheet6 there is some cell that contains the phrase:

happiness is

and we want to retrieve the contents of the cell just to the right of it:

First enter the following UDF in a standard module:

Public Function Find_Range(Find_Item As Variant, _
    Search_Range As Range, _
    Optional LookIn As Variant, _
    Optional LookAt As Variant, _
    Optional MatchCase As Boolean) As String

    Dim c As Range
    If IsMissing(LookIn) Then LookIn = xlValues 'xlFormulas
    If IsMissing(LookAt) Then LookAt = xlPart 'xlWhole
    If IsMissing(MatchCase) Then MatchCase = False
    With Search_Range
        Set c = .Find( _
        What:=Find_Item, _
        LookIn:=LookIn, _
        LookAt:=LookAt, _
        SearchOrder:=xlByRows, _
        SearchDirection:=xlNext, _
        MatchCase:=MatchCase, _
        SearchFormat:=False)
        If Not c Is Nothing Then
             Find_Range = Search_Range.Parent.Name & "!" & c.Address
        End If
    End With
End Function

The UDF will search for Find_Item and return the address as a string. So:

=find_range("happiness is",Sheet6!1:1048576)

will return:

Sheet6!$E$13

Note that the search range is the entire Sheet6 . But we want an OFFSET() , so pick some cell in Sheet5 and enter:

=OFFSET(INDIRECT(find_range("happiness is",Sheet6!1:1048576)),0,1)

User Defined Functions (UDFs) are very easy to install and use:

1. ALT-F11 brings up the VBE window
2. ALT-I ALT-M opens a fresh module
3. paste the stuff in and close the VBE window

If you save the workbook, the UDF will be saved with it. If you are using a version of Excel later then 2003, you must save the file as .xlsm rather than .xlsx

To remove the UDF:

1. bring up the VBE window as above
2. clear the code out
3. close the VBE window

To use the UDF from Excel:

=Find_Range(A1,C1:X100)

To learn more about macros in general, see:

http://www.mvps.org/dmcritchie/excel/getstarted.htm

and

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

and for specifics on UDFs, see:

http://www.cpearson.com/excel/WritingFunctionsInVBA.aspx

Macros must be enabled for this to work!