VBA Excel 用户窗体。 如何判断哪张图片被点击

Question

I have a userform with 10 images inside 10 ImageBoxes. I know that I can determine what image has been clicked like this:

Private Sub Image1_Click()
    MsgBox "Image 1 clicked!"
End Sub

But as there are 10 images, do I have to repeat 10 times the above code?

Private Sub Image1_Click()
    MsgBox "Image 1 clicked!"
End Sub

Private Sub Image2_Click()
    MsgBox "Image 2 clicked!"
End Sub

Private Sub Image3_Click()
    MsgBox "Image 3 clicked!"
End Sub

Private Sub Image4_Click()
    MsgBox "Image 4 clicked!"
End Sub

etc

Or there's a more elegant and concise method?

Answer 1

You need to use event sinking, so in a class module, called cls_CustomImage have the following

Private WithEvents customImage As Image

Public Sub InitialiseCustomImage(imgToCusomise As Image)
    Set customImage = imgToCusomise
End Sub
Private Sub customImage_Click()
    MsgBox customImage.Name
End Sub

Then in your user form opening have the following

Public colCustomImages As Collection

Private Sub UserForm_Initialize()
Dim ctl As Control
Dim clsCustomImage As cls_CustomImage

Set colCustomImages = New Collection

For Each ctl In Me.Controls

    If TypeName(ctl) = "Image" Then
        Set clsCustomImage = New cls_CustomImage
        clsCustomImage.InitialiseCustomImage ctl
        colCustomImages.Add clsCustomImage
    End If

Next ctl
End Sub