VBA while循环不起作用-访问表格

Question

I have a main form with a subform below it. The main form has a "overwrite" option where I can type in a value within txtComments and this will then input a value in the subform.comments field only if its check box has a true value (eg. its checked)

As it stands I'm using this code which works only for the select row of data not the entire subform dataset:

(note: I've simplified the names of the fields and values)

Private Sub Command118_Click()

    Dim rst As Recordset, i As Integer

    Set rst = Subform.RecordsetClone
    i = 0
    rst.MoveFirst
    Do While Not rst.EOF
        i = i + 1
        rst.Edit

        If [SubformCheckbox] = True Then
            [SubformComments] = [txtComments]
        Else
            [SubformComments] = 0
        End If

        rst.Update
        rst.MoveNext
    Loop

    rst.Close
    Set rst = Nothing
End Sub

Answer 1

You used wrong variables. Try this:

    If rst![SubformCheckbox] = True Then
        rst![SubformComments] = [txtComments]
    Else
        rst![SubformComments] = 0
    End If

If you want to do not touch not checked records, change the loop like this:

With rst
    Do While Not .EOF
        If ![SubformCheckbox] = True Then
            .Edit
            ![SubformComments] = [txtComments]
            .Update
        End If
        .MoveNext
    Loop
End With

For performance improvement you can filter the recordset leaving checked rows only, then update all of them in the loop, but best performance will be reached if you'll use UPDATE SQL query for updating the table directly, without using recordset at all.