68K汇编，如何复制数据寄存器的前4位

Question

Suppose an arbitrary data register contains the value '000E0015'. How can I copy the first 4 bits (000E) to another data register?

Answer 1

You need to provide more information for a good answer.

First, 000E0015 is a 32 bit value. The "first four" bits could mean the most significant bits, the 0 that leads it. Or it could mean the lowest four bits, the 5. Or you could mean what you typed- the 000E- which is the first sixteen bits (each four bit group is called a 'nibble').

Second, what is your desired end state? If you begin with 000E0015 in a register, and you have XXXXXXXX in the destination register, do you want it to be 000EXXXX, preserving the values? Are you ok with it being 000E0000? Or do you want the register to be something like 0000000E?

I will assume, until you state otherwise, that you would like the second register to get the 000E, as you state. In that case, assuming you begin in d0 and want to go to d1:

move.l  d1,d0
swap    d1   

This will first copy the entire 32 bit register to d1, then it will swap the words. d1 will contain 0015000E. If you wanted to clear them, you could AND d1 with 0000FFFF. If you wanted them to contain whatever they did before, you could first prepare the 0000000E in an intermediate register, then clear the low bits by ANDing with FFFF0000, then bring in the 0000000E from the intermediate register with an OR- but I'm not quite sure what you need exactly.

Answer 2

You are wanting the most significant word, not 1st 4 bits, so the most significant 16 bits of the 32 bit value. There are a few ways you could do this. If you are only going to deal with that word as a word and ignore anything else in the data register then you could use swap safely.

move.l #$000E0015,d0   ; so this example makes sense :)
move.l d0,d1  ; Move the WHOLE value into your target register
swap d1   ; This will swap the upper and lower words of the register

After this d1 will contain #$0015000E so if you address it only as a word you will access purely the $000E portion of the data register.

move.w d1,$1234  ; Will store the value $000E at address $1234

Now, if you are planning to use the rest of the data register, or perform operations with or on this that will extend beyond the 1st word, you need to make sure that the upper word is clear. You can do this easily enough, 1st instead of using swap, use lsr.l

move.l #$000E0015,d0   ; so this example makes sense :)
move.l d0,d1  ; Move the WHOLE value into your target register
moveq  #16,d2  ; Number of bits to move right by
lsr.l  d2,d1  ; Move Value in d1 right by number of bits specified in d2

You cannot use lsr.l #16,d1 as the immediate value of lsX.l is limited to 8, but you can specify up to 32 in another register and perform the operation that way.

A cleaner (IMHO) way (unless you were repeating this operation multiple times) would be to use AND to clean up the register after the swap.

move.l #$000E0015,d0 ; so this example makes sense :)
move.l d0,d1         ; Move the WHOLE value into your target register
swap   d1            ; This will swap the upper and lower words of the register
and.l  #$ffff,d1     ; Mask off just the data we want

This will remove all bits from the d1 register that do not fit in with the logical mask. IE bit is set true in both d1 and the pattern specified ($ffff)

Finally, what I think might be the most efficient and cleanest way of performing this task would be to use clr and swap.

move.l #$000E0015,d0 ; so this example makes sense :)
move.l d0,d1         ; Move the WHOLE value into your target register
clr.w  d1            ; clear the lower word of the data register 1st
swap   d1            ; This will swap the upper and lower words of the register

Hope those are of some help ? :)