在Excel中找到匹配行的最后一个值

Question

I want to find out last occurrence of particular value and if it is there apply some formula.

Machine Starttime             Alert
a       10/19/2016 12:16:15   S
a       10/19/2016 12:18:15   E
a       10/19/2016 12:19:20   S
b       10/19/2016 12:21:45   S
b       10/19/2016 12:21:48   S
b       10/19/2016 12:21:55   E
a       10/19/2016 12:23:15   S
a       10/19/2016 12:27:30   E

Machine column will have machine name, Starttime is log time of that particular event and alert can be start of End.

I need output like following:

Machine Starttime   Alert   Difference
a   10/19/2016 12:16:15 S   
a   10/19/2016 12:18:15 E   120
a   10/19/2016 12:19:20 S   
b   10/19/2016 12:21:45 S   
b   10/19/2016 12:21:48 S   
b   10/19/2016 12:21:55 E   10
a   10/19/2016 12:23:15 S   
a   10/19/2016 12:27:30 E   490

Difference will be populated only in case of E and there is corresponding start event for that machine, if there are more than one start event then pick first one. I just want to understand if it is possible with just excel formula(without macro)? if yes, how?

I already tried it using index function without success

=IF(C3="E",MATCH(A3,A2:$A$2,0),"")

Answer 1

Yes it is possible but it is not easy. You have to use an array formula to solve this. The formula would be:

=IF(C2="S","",(B2-MIN(IF($A$2:A2=A2,IF($C$2:C2="S",IF(ROW($A$2:A2)>MAX(IF(ROW($A$2:A2)<ROW(A2),IF($A$2:A2=A2,IF($C$2:C2="E",ROW($A$2:A2))))),$B$2:B2)))))*86400)

First data row is 2, column A has the machine names, column B the log times, column c the "S"/"E". Put the formula in column D in the first data row and push CTRL+SHIFT+ENTER to make it an array formula. You should see {} around the formula now. Copy the cell (CTRL+C) and paste it into all rows except the row where the formula is already in.

If you need any more help, place a comment.

Answer 2

It can be done with some complicated array formula, but a helper formula can make it easier to distinguish the groups. For example in D2 :

= ( ABS(N(D1))+($A2<>$A1) ) * IF(C2="S",1,-1)

and the final Index + Match formula next to it in E2 :

=IF($C2="E", ROUND( ($B2 - INDEX($B$2:$B$9, MATCH(ABS($D2),$D$2:$D$9,0) ) )*24*60*60,0),"")

With your sample data, it should result in something like this:

A       B                   C       D       E
-----------------------------------------------------------
Machine Starttime           Alert   Group   Index+Match
a       10/19/2016 12:16    S        1      
a       10/19/2016 12:18    E       -1      120
a       10/19/2016 12:19    S        1      
b       10/19/2016 12:21    S        2      
b       10/19/2016 12:21    S        2      
b       10/19/2016 12:21    E       -2      10
a       10/19/2016 12:23    S        3      
a       10/19/2016 12:27    E       -3      255