Excel VBA工作表更改效率

Question

I have a worksheet with several worksheet change events. Unfortunately, I am getting some memory errors due to them. I was wondering if anyone could look at this code snippet and let me know if it could be written more efficiently?

This worksheet change event calls another macro if and only if cell K4 = "Event Based" and every one of the following cells have something in them: J12:J15, M12:M14. I can call the macro if cells J12:J15, M12:M14 are already filled in and K4 is changed to "Event Based"

Private Sub Worksheet_Change(ByVal Target As Range)
If Range("J12") <> "" And _
Range("J13") <> "" And _
Range("J14") <> "" And _
Range("J15") <> "" And _
Range("M12") <> "" And _
Range("M13") <> "" And _
Range("M14") <> "" Then
Dim ZRange As Range
Set ZRange = Range("K4")
If ZRange = "Event Based" Then
If Union(Target, ZRange).Address = ZRange.Address Then
Application.EnableEvents = False
Call EventBasedYes
Application.EnableEvents = True

End If
End If
End If

My problem is, I have written a different worksheet change event for each individual cell. The following fires if K4="Event Based" and J13:J15 have something in them and then data is addded to J12

If Range("K4") = "Event Based" And _
Range("J13") <> "" And _
Range("J14") <> "" And _
Range("J15") <> "" And _
Range("M12") <> "" And _
Range("M13") <> "" And _
Range("M14") <> "" Then
Dim FRange As Range
Set FRange = Range("J12")
If FRange <> "" Then
If Union(Target, FRange).Address = FRange.Address Then
Application.EnableEvents = False
Call EventBasedYes
Application.EnableEvents = True

End If
End If
End If

I don't know how to write ONE event such that if all cells are filled, the macro is called and such that if any one cell is cleared, a macro named EventBasedNo. Sorry, I am not very experienced with VBA code. I'm sure there's a way to do this.

Answer 1

Regarding speed improvements:

One thing you could do would be to not execute a lot of tests on cell values unless you know that there is a possibility that you are going to need to do that test.

So your current code says:

If Range("J12") <> "" And _
   Range("J13") <> "" And _
   Range("J14") <> "" And _
   Range("J15") <> "" And _
   Range("M12") <> "" And _
   Range("M13") <> "" And _
   Range("M14") <> "" Then
    Dim ZRange As Range
    Set ZRange = Range("K4")
    If ZRange = "Event Based" Then
        If Union(Target, ZRange).Address = ZRange.Address Then
            Application.EnableEvents = False
            Call EventBasedYes
            Application.EnableEvents = True
        End If
    End If
End If

which means that you are looking up the values of J12 , J13 , J14 , J15 , M12 , M13 , M14 and K4 , and then deciding whether the worksheet change happened in a cell you are interested in.

By moving the test regarding Target 's location earlier, you can save those lookups:

If Not Application.Intersect(Target, Range("K4")) Is Nothing Then
    If Range("J12") <> "" And _
       Range("J13") <> "" And _
       Range("J14") <> "" And _
       Range("J15") <> "" And _
       Range("M12") <> "" And _
       Range("M13") <> "" And _
       Range("M14") <> "" Then
        Dim ZRange As Range
        Set ZRange = Range("K4")
        If ZRange = "Event Based" Then
            Application.EnableEvents = False
            Call EventBasedYes
            Application.EnableEvents = True
        End If
    End If
End If

---

If a lot of the cells you are checking are likely to be part of the Target of a single Worksheet_Change event then you may be better off testing for all the cells you are interested in first, ie using something like:

If Not Application.Intersect(Target, Range("K4,J12,X47")) Is Nothing Then

and then storing the values of the cells that you are frequently referring to in variables (or a Variant array if they are in a contiguous block?) so that you can refer to the variables multiple times rather than have to access the cell itself multiple times.

---

PS Union(Target, ZRange).Address = ZRange.Address is equivalent to Target.Address = ZRange.Address . Is it intentional that your code only fires if a single cell is changed (ie you don't want the code to run if cells K2:K6 are changed in a single event, only if K4 is changed by itself)? My proposed change uses an Intersect , which will run if the changed range includes the cell you are interested in, so you should change that back if you don't want that to happen.

---

Possible rewrite

I think I understand what you are trying to do. Perhaps the following code will do all your tests at once:

If Not Application.Intersect(Target, Range("K4,J12:J15,M12:M14")) Is Nothing Then
    Application.EnableEvents = False
    If Range("J12").Value <> "" And _
       Range("J13").Value <> "" And _
       Range("J14").Value <> "" And _
       Range("J15").Value <> "" And _
       Range("M12").Value <> "" And _
       Range("M13").Value <> "" And _
       Range("M14").Value <> "" And _
       Range("K4").Value = "Event Based" Then
        Call EventBasedYes
    Else
        Call EventBasedNo
    End If
    Application.EnableEvents = True
End If