Delphi Indy与RECON的TCP连接

Question

I am trying to figure out how would be possible to get a connection and authentication stablished with the remote console.

This Wiki Wiki 1 and this one Wiki 2 tell me I need to build a packet and send it to the RECON, but I do not know how to do this..

I am a newbie with networking but since I was searching over there then I build this:

procedure TForm1.Button1Click(Sender: TObject);
begin
  IdTCPClient1.Host:= '127.0.0.1';
  IdTCPClient1.Port:= 20001;
  IdTCPClient1.Connect;
  IdTcpClient1.IOHandler.Writeln('1234');
  ShowMessage(IdTcpClient1.IOHandler.ReadLn);
end; 

I am stucked there, where 1234 is the RECON password and the message that it return: Connection closed gracefully...

Finally, how can I log in successfully? And at least send a command "list" the next step would be receive the console log in realtime?

Thanks

Answer 1

Your code is not implementing the Source RECON protocol that the Minecraft commands run on top of. You can't just send arbitrary data to the server, it has to be framed properly.

Try something more like this instead:

const
  SERVERDATA_AUTH = 3;
  SERVERDATA_AUTH_RESPONSE = 2;
  SERVERDATA_EXECCOMMAND = 2;
  SERVERDATA_RESPONSE_VALUE = 0;

procedure TForm1.Button1Click(Sender: TObject);
begin
  IdTCPClient1.Host := '127.0.0.1';
  IdTCPClient1.Port := 20001;
  IdTCPClient1.Connect;
  SendRECONLogin('1234');
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  IdTCPClient1.Disconnect;
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  SendRECONCommand('list');
end;

procedure TForm1.IdTCPClient1Connect(Sender: TObject);
begin
  Timer1.Enabled := True;
end; 

procedure TForm1.IdTCPClient1Disconnect(Sender: TObject);
begin
  Timer1.Enabled := False;
end; 

procedure TForm1.Timer1Timer(Sender: TObject);
var
  RespID: Int32;
  PktType: Int32;
  Payload: string;
begin
  try
    if not IdTCPClient1.Connected then
      Exit;

    if IdTCPClient1.IOHandler.InputBufferIsEmpty then
    begin
      IdTCPClient1.IOHandler.CheckForDataOnSource(0);
      IdTCPClient1.IOHandler.CheckForDisconnect(True, False);
      if IdTCPClient1.IOHandler.InputBufferIsEmpty then Exit;
    end;

    RespID := ReadRECONPacket(PktType, Payload);
    case PktType of
      SERVERDATA_AUTH_RESPONSE: begin
        if RespID = -1 then begin
          // authentication failed...
          IdTCPClient1.Disconnect;
        end else begin
          // authentication successful...
        end;
      end;
      SERVERDATA_RESPONSE_VALUE: begin
        // match RespID to previously sent ReqID
        // and handle Payload as needed...
      end;
    end;
  except
    IdTCPClient1.Disconnect;
  end;
end;

var
  gReqID: Int32 = 0;

function TForm1.SendRECONPacket(PktType: Int32; const Payload: string = ''): Int32;
var
  Bytes: TIdBytes;
begin
  Bytes := IndyTextEncoding_ASCII.GetBytes(Payload);
  try
    if gReqID < MaxInt then Inc(gReqID)
    else gReqID := 1;
    Result := gReqID;

    IdTCPClient1.IOHandler.WriteBufferOpen;
    try
      IdTCPClient1.IOHandler.Write(Int32(Length(Bytes)+10), False);
      IdTCPClient1.IOHandler.Write(Result, False);
      IdTCPClient1.IOHandler.Write(PktType, False);
      IdTCPClient1.IOHandler.Write(Bytes);
      IdTCPClient1.IOHandler.Write(UInt16(0), False);
      IdTCPClient1.IOHandler.WriteBufferClose;
    except
      IdTCPClient1.IOHandler.WriteBufferCancel;
      raise;
    end;
  except
    IdTCPClient1.Disconnect;
    raise;
  end;    
end;

function TForm1.SendRECONLogin(const Password: String): Int32;
begin
  Result := SendRECONPacket(SERVERDATA_AUTH, Password);
end;

function TForm1.SendRECONCommand(const Cmd: String): Int32;
begin
  Result := SendRECONPacket(SERVERDATA_EXECCOMMAND, Cmd);
end;

function TForm1.ReadRECONPacket(var PktType: Integer; var Payload: String): Int32;
var
  Len: Int32;
begin
  try
    Len     := IdTCPClient1.IOHandler.ReadInt32(False);
    Result  := IdTCPClient1.IOHandler.ReadInt32(False);
    PktType := IdTCPClient1.IOHandler.ReadInt32(False);
    Payload := IdTCPClient1.IOHandler.ReadString(Len-10, IndyTextEncoding_ASCII);
    IdTCPClient1.IOHandler.Discard(2);
  except
    IdTCPClient1.Disconnect;
    raise;
  end;
end;

Note that RCON is an asynchronous protocol. Each command contains a request ID, which is echoed back in the response. Multiple commands can be sent to the server without waiting for their replies. That is why I wrote SendRCONPacket() to return the request ID actually used, so you can save it off somewhere and match it to the response ID returned by ReadRCONPacket() . The use of a TTimer in the above code is just an example of how to receive unsolicited data from the server. In production code, I would suggest using a dedicated reading thread instead of a timer, and let the thread notify the rest of your code whenever a packet arrives.

If you are not planning on ever having multiple commands being processed in parallel, then you could get rid of the timer altogether and do something more like this instead:

const
  SERVERDATA_AUTH = 3;
  SERVERDATA_AUTH_RESPONSE = 2;
  SERVERDATA_EXECCOMMAND = 2;
  SERVERDATA_RESPONSE_VALUE = 0;

procedure TForm1.Button1Click(Sender: TObject);
var
  Reply: string;
begin
  IdTCPClient1.Host := '127.0.0.1';
  IdTCPClient1.Port := 20001;
  IdTCPClient1.Connect;
  SendRECONLogin('1234');
  ShowMessage('Conectado exitosamente');
  Reply := SendRECONCommand('say Hello');
  // use Reply as needed...
  ShowMessage(Reply);
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  IdTCPClient1.Disconnect;
end;

procedure TForm1.Button3Click(Sender: TObject);
var
  Reply: string;
begin
  Reply := SendRECONCommand('list');
  // use Reply as needed...
  ShowMessage(Reply);
end;

var
  gReqID: Int32 = 0;

function TForm1.SendRECONPacket(PktType: Int32; const Payload: string = ''): Int32;
var
  Bytes: TIdBytes;
begin
  Bytes := IndyTextEncoding_ASCII.GetBytes(Payload);
  try
    if gReqID < MaxInt then Inc(gReqID)
    else gReqID := 1;
    Result := gReqID;

    IdTCPClient1.IOHandler.WriteBufferOpen;
    try
      IdTCPClient1.IOHandler.Write(Int32(Length(Bytes)+10), False);
      IdTCPClient1.IOHandler.Write(Result, False);
      IdTCPClient1.IOHandler.Write(PktType, False);
      IdTCPClient1.IOHandler.Write(Bytes);
      IdTCPClient1.IOHandler.Write(UInt16(0), False);
      IdTCPClient1.IOHandler.WriteBufferClose;
    except
      IdTCPClient1.IOHandler.WriteBufferCancel;
      raise;
    end;
  except
    IdTCPClient1.Disconnect;
    raise;
  end;
end;

procedure TForm1.SendRECONLogin(const Password: String);
var
  ReqID, RespID, PktType: Int32;
  Reply: String;
begin
  {
  From https://developer.valvesoftware.com/wiki/Source_RCON_Protocol#SERVERDATA_AUTH_RESPONSE:

  When the server receives an auth request, it will respond with an empty SERVERDATA_RESPONSE_VALUE,
  followed immediately by a SERVERDATA_AUTH_RESPONSE indicating whether authentication succeeded or
  failed. Note that the status code is returned in the packet id field, so when pairing the response with the
  original auth request, you may need to look at the packet id of the preceeding SERVERDATA_RESPONSE_VALUE.
  }

  // in testing, there is no empty SERVERDATA_RESPONSE_VALUE sent before SERVERDATA_AUTH_RESPONSE!

  ReqID := SendRECONPacket(SERVERDATA_AUTH, Password);

  RespID := ReadRECONPacket(PktType, Reply);
  if PktType = SERVERDATA_RESPONSE_VALUE then
  begin
    if RespID <> ReqID then
      raise Exception.Create('Received unexpected packet');
    RespID := ReadRECONPacket(PktType, Reply);
  end;

  if PktType <> SERVERDATA_AUTH_RESPONSE then
    raise Exception.Create('Received unexpected packet');

  if RespID <> ReqID then
  begin
    if RespID <> -1 then
      raise Exception.Create('Received unexpected packet');
    raise Exception.Create('Authentication failed');
  end;
end;

function TForm1.SendRECONCommand(const Cmd: String): string;
var
  ReqID, TermReqID, RespID, PktType: Int32;
  Reply: string;
begin
  {
  From https://developer.valvesoftware.com/wiki/Source_RCON_Protocol#Multiple-packet_Responses:

  Most responses are small enough to fit within the maximum possible packet size of 4096 bytes.
  However, a few commands such as cvarlist and, occasionally, status produce responses too
  long to be sent in one response packet. When this happens, the server will split the response
  into multiple SERVERDATA_RESPONSE_VALUE packets. Unfortunately, it can be difficult to
  accurately determine from the first packet alone whether the response has been split.

  One common workaround is for the client to send an empty SERVERDATA_RESPONSE_VALUE
  packet after every SERVERDATA_EXECCOMMAND request. Rather than throwing out the
  erroneous request, SRCDS mirrors it back to the client, followed by another RESPONSE_VALUE
  packet containing 0x0000 0001 0000 0000 in the packet body field. Because SRCDS always
  responds to requests in the order it receives them, receiving a response packet with an empty
  packet body guarantees that all of the meaningful response packets have already been received.
  Then, the response bodies can simply be concatenated to build the full response.
  }

  // in testing, there is no mirrored SERVERDATA_RESPONSE_VALUE!  The sent SERVERDATA_RESPONSE_VALUE
  // is responded with a single SERVERDATA_RESPONSE_VALUE that says 'Unknown request' in its payload!

  ReqID := SendRECONPacket(SERVERDATA_EXECCOMMAND, Cmd);
  TermReqID := SendRECONPacket(SERVERDATA_RESPONSE_VALUE, '');

  repeat
    RespID := ReadRECONPacket(PktType, Reply);
    if PktType <> SERVERDATA_RESPONSE_VALUE then
      raise Exception.Create('Received unexpected packet');

    if RespID <> ReqID then
    begin
      if RespID <> TermReqID then
        raise Exception.Create('Received unexpected packet');

      {
      RespID := ReadRECONPacket(PktType, Reply);
      if (PktType <> SERVERDATA_RESPONSE_VALUE) or (RespID <> TermReqID) then
        raise Exception.Create('Received unexpected packet');
      }

      Break;
    end;

    Result := Result + Reply;
  until False;
end;

function TForm1.ReadRECONPacket(var PktType: Integer; var Payload: String): Int32;
var
  Len: Int32;
begin
  try
    Len := IdTCPClient1.IOHandler.ReadInt32(False);
    Result := IdTCPClient1.IOHandler.ReadInt32(False);
    PktType := IdTCPClient1.IOHandler.ReadInt32(False);
    Payload := IdTCPClient1.IOHandler.ReadString(Len-10, IndyTextEncoding_ASCII);
    IdTCPClient1.IOHandler.Discard(2);
  except
    IdTCPClient1.Disconnect;
    raise;
  end;
end;