调整图像大小功能不保存任何内容

Question

Trying to resize an image but the following function I found doesn't produce any outcome. I figure that the function needs to save bitmap to file, so I added that code.. but nothing is saved. All ahk files and images are in the same folder.

#Include Gdip.ahk

If !pToken := Gdip_Startup()
{
    MsgBox, 48, gdiplus error!, Gdiplus failed to start. Please ensure you have gdiplus on your system
    ExitApp
}
pBitmap := "test.bmp"
pResizedBitmap := Gdip_ResizeBitmap(pBitmap, 200, 0)
Gdip_SaveBitmapToFile(pResizedBitmap, "Resize.png")
Gdip_Shutdown(pToken)
MsgBox

Gdip_ResizeBitmap(pBitmap, PercentOrWH, Dispose=1) {    ; returns resized bitmap. By Learning one.
    Gdip_GetImageDimensions(pBitmap, origW, origH)
    if PercentOrWH contains w,h
    {
        RegExMatch(PercentOrWH, "i)w(\d*)", w), RegExMatch(PercentOrWH, "i)h(\d*)", h)
        NewWidth := w1, NewHeight := h1
        NewWidth := (NewWidth = "") ? origW/(origH/NewHeight) : NewWidth
        NewHeight := (NewHeight = "") ? origH/(origW/NewWidth) : NewHeight
    }
    else
    NewWidth := origW*PercentOrWH/100, NewHeight := origH*PercentOrWH/100       
    pBitmap2 := Gdip_CreateBitmap(NewWidth, NewHeight)
    G2 := Gdip_GraphicsFromImage(pBitmap2), Gdip_SetSmoothingMode(G2, 4), Gdip_SetInterpolationMode(G2, 7)
    Gdip_DrawImage(G2, pBitmap, 0, 0, NewWidth, NewHeight)
    Gdip_DeleteGraphics(G2)
    if Dispose
        Gdip_DisposeImage(pBitmap)
    return pBitmap2
}

Any help would be much appreciated!

Answer 1

pBitmap := "test.bmp"

Won't work. You have to invoke Gdip_CreateBitmapFromFile() function from Gdip library to create pointer to bitmap. In example 6 you can see it being used.

Like that (the rest should work):

pBitmap := Gdip_CreateBitmapFromFile("test.bmp")