如何在Excel VBA中过滤后获取可见行数

Question

In my Excel sheet I am applying a filter and after that I am counting the visible rows. I used the following code but I'm getting a wrong count. When I have xlCellTypeVisible it shows "12" records instead of "14" records and visibleTotal variable shows "0" count.

Dim ws As Worksheet
Dim rng As Range
Dim visibleTotal As Long

'xlwkbOutput.Sheets("Sheet1")
Set rng = xlwkbOutput.Sheets("Sheet1").Range("A1:T" & lastRow&)

xlwkbOutput.Sheets("Sheet1").AutoFilterMode = False
rng.AutoFilter field:=1, Criteria1:="#N/A"

visibleTotal = Application.WorksheetFunction.Sum(rng.SpecialCells(xlCellTypeVisible))
' print to the immediate window
Debug.Print visibleTotal

Answer 1

Maybe you can make use of SUBTOTAL function. This function is used very often when you have filtered values. You can adapt your code to:

' To SUM filtered rows use 9 as argument of SUBTOTAL or to COUNTA use 3
' "- 1" is to exclude the first row, probably the header of your range; otherwise remove it
visibleTotal = Application.WorksheetFunction.Subtotal(9, rng) - 1 

SUBTOTAL Arguments List:

1   AVERAGE
2   COUNT
3   COUNTA
4   MAX
5   MIN
6   PRODUCT
7   STDEV
8   STDEVP
9   SUM
10  VAR
11  VARP

For more information about this function you can check the link.

HTH ;)

Answer 2

your narrative is about "counting the visible rows" while your code shows a SUM() function

anyhow here's how you can get both numbers, keeping in mind that Autofilter() will always filter header row, ie the 1st row of the range it's being called upon

Option Explicit

Sub main()
    Dim visibleTotal As Long, visibleRows As Long

    With xlwkbOutput.Sheets("Sheet1") '<-- reference your worksheet
        .AutoFilterMode = False
        With .Range("A1:T5") '<-- reference its relevant range
            .AutoFilter field:=1, Criteria1:="#N/A" '<-- apply filter: first row (headers) will always be selected
            visibleRows = Application.WorksheetFunction.Subtotal(103, .Resize(, 1)) - 1 '<-- count visible rows, excluding headers (always filtered)
            If visibleRows > 0 Then visibleTotal = Application.WorksheetFunction.Sum(.Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible)) '<-- sum all visible cells, excluding headers (always filtered)
            ' print to the immediate window
            Debug.Print visibleTotal
        End With
        .AutoFilterMode = False
    End With
End Sub

Answer 3

I don't know, don't you want to use Count function instead? It is hard to say, but the behaviour seems correct to me. It is hard to say, when we don't have data. Try to apply sum function in worksheet on visible cells, and check what it returns, if it is same as in macro.