清除宏可清除特定列中空白单元格上特定范围的单元格

Question

I asked a similar question yesterday to populate a range of cells within a specific list of columns. That aspect of my code is working perfectly, but now I am trying to create a clear macro to delete the inserted rows.

All of the newly inserted rows will have blank cells in column N, so I am simply trying to search all cells in column N, find the blanks, then delete the row between columns N and Y. This is what I have so far, but it is not doing anything when I run it?

Any help is greatly appreciated!

Sub Clear_PCOTCS()
    Dim myLastRow As Long
    Dim myRow As Long

    Application.ScreenUpdating = False
    myLastRow = Cells(Rows.Count, "N").End(xlUp).Row
    For myRow = myLastRow To 1 Step -1
        If Len(Cells(myRow, "N")) = 1 And Cells(myRow, "N") = "" Then
            Range(Cells(myRow + 1, "N"), Cells(myRow + 1, "Y")).Delete  Shift:=xlDown 'CopyOrigin:=xlFormatFromLeftOrAbove
        End If
    Next myRow
    Application.ScreenUpdating = True
End Sub

Answer 1

Your error is coming from passing a bad enum to Range.Delete . It expects an XlDeleteShiftDirection value, and you're passing it an XlDirection . Note that although xlShiftUp and xlUp share the same value, xlDown (-4121) is not a valid XlDeleteShiftDirection .

If all you need to do is delete every row (between columns "N" and "Y") when the cell in column "N" is empty, you're over-thinking it. First, the shift should default to xlShiftUp based on the shape of the Range that you're creating to delete, so you can simply omit the parameter. Second, you need to remove the offset you're applying here:

Range(Cells(myRow + 1, "N"), Cells(myRow + 1, "Y")).Delete

Delete the row that you're testing, not the one below it. You should be looking for something more like this:

Sub Clear_PCOTCS()
    Dim myLastRow As Long
    Dim myRow As Long

    Application.ScreenUpdating = False
    myLastRow = Cells(Rows.Count, 14).End(xlUp).Row
    For myRow = myLastRow To 1 Step -1
        If Cells(myRow, 14).Value = vbNullString Then
            Range(Cells(myRow, 14), Cells(myRow, 25)).Delete
        End If
    Next myRow
    Application.ScreenUpdating = True
End Sub