批处理-仅对具有特定名称的文件夹中的文件执行操作

Question

I have the following FOR statement:

 FOR /R %%i IN ("*.wmv") DO "7za.exe" -sdel a -mx0 -tzip -pPASSWORDHERE -mem=AES256 -y "%%~dpni.zip" "%%i" 

that when ran at the root folder of any given directory, it will zip all files matching the defined wildcard (wmv files, in this case), producing an encrypted ZIP file, keeping the original name.

What I need to do is to tell this script to act ONLY on folders that have a specific name. Here's an example:

I have a directory structure that resembles this (and will contain wmv files in subdirectories within them):

root
 |-20120211
   |-20
   |-21
 |-20130425
   |-34
   |-21
 |-20140516
   |-10
   |-22
 |-20150728
   |-230
   |-213
 and so on...

And what I need to do is, for example, to only zip all the files that are inside of the last folder, which filename starts with 2015*

To accomplish this, I've tried concatenating FOR statements, more specifically, something like:

 FOR /D %%P IN (2015*) DO (run my other FOR here)

but the only thing it accomplishes is just to verify if a folder's name within that structure matches "2015*", and if it does... well... it just zips everything, all the files in all folders, not just those that start with "2015".

I've searched the web but found no actual example that could help me with this. If you could aid me in achieving this, I'll be beholden to you =)

Thanks a million in advance!

Answer 1

FOR /D %%P IN (2015*) DO PUSHD "%%P"&(FOR /R %%i IN ("*.wmv") DO ECHO %%i)&POPD

should accomplish the task, given the description.

Filename simply echo ed. Remember that the current directory will be the file-to-be-archived's directory at the time the echo is executed, so replacing the echo with the archive instruction will require the required destination directory be specified

Answer 2

Assuming that the items 20 , 21 , etc., are folders as well, which contain all the *.wmv files, the following should work:

for /D %%D in ("root\2015*") do (
    for /D %%E in ("%%~D\*") do (
        for %%F in ("%%~E\*.wmv") do (
            "7za.exe" -sdel a -mx0 -tzip -pPASSWORDHERE -mem=AES256 -y "%%~dpnF.zip" "%%~F"
        )
    )
)

---

In case the *.wmv files may also be located in the parent folders like 20150728 , you could nest a for /R loop in a for /D loop, like this:

for /D %%D in ("root\2015*") do (
    call :SUB "%%~D"
)
exit /B

:SUB
for /R "%~1" %%F in ("*.wmv") do (
    "7za.exe" -sdel a -mx0 -tzip -pPASSWORDHERE -mem=AES256 -y "%%~dpnF.zip" "%%~F"
)
exit /B

You need a sub-routine here, because for /R does not accept other for variables to be used as the root after /R . This is due to the fact that the root is applied in a very early parsing stage where for variables are not yet processed/expanded.