使用XSLT从两个XML文件中获取数据并合并到一个文件中？

Question

I'm trying to merge two tables using XSLT 1.0.

I have a representation of two DB tables in XML. The first table is a set of key-value pairs:

Table1.xml

<table>
  <row>
    <column name="key">key1</column>
    <column name="value">val1</column>
  </row>
  <row>
    <column name="key">key2</column>
    <column name="value">val2</column>
  </row>
</table>

The second table has rows of data:

Table2.xml

<table>
  <row>
    <column name="A">a1</column>
    <column name="B">b1</column>
    <column name="C">c1</column>
  </row>
  <row>
    <column name="A">a2</column>
    <column name="B">b2</column>
    <column name="C">c2</column>
  </row>
</table>

I am trying to take one of the key-value pairs and add insert it as a new column in every row so that it ends up with this:

Output.xml

<table>
  <row>
    <column name="A">a1</column>
    <column name="B">b1</column>
    <column name="C">c1</column>
    <column name="key1">val1</column>
  </row>
  <row>
    <column name="A">a2</column>
    <column name="B">b2</column>
    <column name="C">c2</column>
    <column name="key1">val1</column>
  </row>
</table>

Answer 1

Here are the two main ingredients of the solution:

<xsl:variable name="kvp">
  <xsl:variable name="row" select="doc('table1.xml')/table/row[1]"/>
  <column name="{$row/column[1]}">
    <xsl:value-of select="$row/column[2]"/>
  </column>
</xsl:variable>

<xsl:template match="row">
  <row>
    <xsl:copy-of select="*"/>
    <xsl:copy-of select="$kvp"/>
  </row>
</xsl:template>

Answer 2

I want to select the row where the key is "key1" and create a new column from it in the output table.

Assuming you are processing the Table2.xml file, you can do:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="val" select="document('Table1.xml')/table/row[column[1]='key1']/column[2]" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="row">
    <xsl:copy>
        <xsl:apply-templates/>
        <column name="key1">
            <xsl:value-of select="$val" />
        </column>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>