sed脚本中的循环不会终止

Question

Say I have a file like this:

...
{
     ...
     cout<< "---at time:\t\t"<< sc_core::sc_time_stamp()<<"\n\n" << endl;
     ...
     cout<< "---at time:\t\t"<< sc_core::sc_time_stamp()<<"\n\n" << endl;
     ...
}
...
{
     ...
     if(strcmp(argv[1], "--io_freq1_Mhz") != 0)
     if(strcmp(argv[2], "--io_freq2_Mhz") != 0)
     ...
     if(strcmp(argv[11], "--bytes_per_word") != 0)
     ...
     if(strcmp(argv[23], "--mem_size_bytes") != 0)
     ...
}

What I want do first is, using sed, loading all lines containing the pattern "--foo" into pattern space and printing out just the part inside the paranthesis, so I use the command:

sed -n -e 's/.*[^-]\(-\{2\}[^-].*\)"\(.*\)/\1/p' file

which does exactly what I want, so I get as an output:

--io_freq1_Mhz
--io_freq2_Mhz
...
--bytes_per_word
...
--mem_size_bytes

Next I want to merge all the lines into one and separating the content by a blank. I can solve this using command substitution:

echo `sed -n -e 's/.*[^-]\(-\{2\}[^-].*\)"\(.*\)/\1/p' file`

This gives me:

--io_freq1_Mhz --io_freq2_Mhz --... --bytes_per_word --... --mem_size_bytes

Next I want to insert a number betwenn the parameters, for example 1, so the final result should look like:

--io_freq1_Mhz 1 --io_freq2_Mhz 1 --... 1 --bytes_per_word 1 --... 1 --mem_size_bytes 1

I can almost solve this. I'm using the command:

echo `sed -n -e 's/.*[^-]\(-\{2\}[^-].*\)"\(.*\)/\1/p' file` | sed -n -e ':start { s/\(--[^\ ]*\) -/\1 1 -/p; b start }' | sed -n -e 's/\(--.*[^\ ]\)/\1 1/p'

but I get two minor problems. First of all, before I'm jumping back to my start mark the output gets piped into the last sed statement, that means I get as an output:

--io_freq1_Mhz 1 --io_freq2_Mhz --... --bytes_per_word --... --mem_size_bytes 1
--io_freq1_Mhz 1 --io_freq2_Mhz 1 --... --bytes_per_word --... --mem_size_bytes 1

and so on. So my first question is, how I can avoid piping the output every time into my last sed statement. Can I achieve this using different sed options/flags?

The second problem is, that the command doesn't terminate. The iteration ends with

--io_freq1_Mhz 1 --io_freq2_Mhz 1 --... --bytes_per_word 1 --... --third_last_item 1 --second_last_item mem_size_bytes 1

As can be seen, behind the second last item a '1' isn't appended and additionally the whole command doesn't terminate. I have to terminate it using Ctrl-C.

Answer 1

Use a minor modification of your first command:

sed -n -e 's/.*[^-]\(-\{2\}[^-].*\)"\(.*\)/\1 1/p' file | tr '\n' ' '

Having extracted the name, append the digit after it. The tr command converts newlines into blanks. You could do it all in sed ; it would be fiddly, that's all.

---

Actually, it isn't all that much more fiddly, but it requires a different way of looking at the process. Specifically, you need to save the matching patterns in the hold space, and then process them all at the end of the input:

sed -n \
    -e '/.*[^-]\(-\{2\}[^-].*\)"\(.*\)/{ s//\1 1/; H; }' \
    -e '$ { x; s/\n/ /g; p; }' file 

The semicolons before the } characters are necessary with BSD (macOS) sed , but not with GNU sed . The first -e option finds lines that match your pattern, and then applies a substitute command to the line to retain just the --name part plus a digit 1, and then appends that information to the hold space after a newline. The second -e option works on the last line. It exchanges the pattern and hold spaces, then replaces every newline with a blank and prints the result, including a trailing newline which the script with tr replaces with a blank.

Output (note the leading blank):

 --io_freq1_Mhz 1 --io_freq2_Mhz 1 --bytes_per_word 1 --mem_size_bytes 1

If you don't want the leading blank, remove it before printing (add s/^ //; before the p ).