使用xslt刷新具有相同名称的多个元素的位置

Question

The source xml document:

<item>
 <p languageCode="en">en</p>
 <p languageCode="fr">fr</p>
 <c languageCode="de">de</c>
 <c languageCode="nl">nl</c>
</item>

The needed result of the transformation must be this xml document:

<item>
 <p pos="1">en</p>
 <p pos="2">fr</p>
 <c pos="1">de</c>
 <c pos="2">nl</c>
</item>

using xslt is it possible achieve it?

Answer 1

In XSLT 2.0 you can do:

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:template match="/item">
    <xsl:copy>
        <xsl:for-each-group select="*" group-adjacent="name()"> 
            <xsl:apply-templates select="current-group()"/> 
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

<xsl:template match="p | c">
    <xsl:copy>
        <xsl:attribute name="pos" select="position()"/>
        <xsl:value-of select="."/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

Answer 2

XSLT 1.0:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
   <item><xsl:apply-templates/></item>
 </xsl:template>


     <xsl:template match="/*/*">
      <xsl:copy>
         <xsl:attribute name="pos">
           <xsl:value-of select="count(preceding-sibling::*[name()=name(current())])+1"/>
         </xsl:attribute>
         <xsl:apply-templates/>
       </xsl:copy>
     </xsl:template>
    </xsl:stylesheet>

---

XSLT 2.0 :

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
   <item><xsl:apply-templates/></item>
 </xsl:template>

 <xsl:template match="/*/*">
  <xsl:copy>
     <xsl:attribute name="pos" 
                    select="count(preceding-sibling::*[name()=name(current())])+1"/>
     <xsl:apply-templates/>
   </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

Another XSLT 2.0 solution :

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kByName" match="/*/*" use="name()"/>

 <xsl:template match="/*">
   <item><xsl:apply-templates/></item>
 </xsl:template>

 <xsl:template match="/*/*">
  <xsl:copy>
     <xsl:attribute name="pos" 
                  select="index-of(key('kByName', name())/generate-id(), generate-id())"/>
     <xsl:apply-templates/>
   </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

When applied on the provided XML document :

<item>
    <p languageCode="en">en</p>
    <p languageCode="fr">fr</p>
    <c languageCode="de">de</c>
    <c languageCode="nl">nl</c>
</item>

All three solutions produce the wanted, correct result:

<item>
   <p pos="1">en</p>
   <p pos="2">fr</p>
   <c pos="1">de</c>
   <c pos="2">nl</c>
</item>

Do note :

All these solutions are generic -- they don't depend on the names, number, number of names or order of elements.

For example, when applied on the following XML document:

<item>
    <p languageCode="en">en</p>
    <p languageCode="fr">fr</p>
    <c languageCode="de">de</c>
    <c languageCode="nl">nl</c>
    <d languageCode="es">es</d>
    <d languageCode="bg">bg</d>
    <d languageCode="pl">pl</d>
</item>

all three solutions produce the wanted, correct result :

<item>
   <p pos="1">en</p>
   <p pos="2">fr</p>
   <c pos="1">de</c>
   <c pos="2">nl</c>
   <d pos="1">es</d>
   <d pos="2">bg</d>
   <d pos="3">pl</d>
</item>