查找其他单元格的确切值-Excel-VBA

Question

I want to be able to compare 2 cells in VBA. The issue i'm having is that it's not making an exact match.

Dim WeekNum2 As Integer
WeekNum2 = Cells(1, 12).Value
Range("F2:F60").Find(WeekNum2).Activate
U = ActiveCell.Row
Range(Cells(U, 7), Cells(U, 7)).Value = GreenCountP4
Range(Cells(U, 8), Cells(U, 8)).Value = YellowCountP4
Range(Cells(U, 9), Cells(U, 9)).Value = RedCountP4

Above is the section of code that isn't working ideally. The value in Cells(1,12) is generated using the =WEEKNUM(K1) formula so depending on the date in K1 it returns a value from 1-52. I want it to take this value and then find the equivalent value in the range F2:F60.

In F2:F60 i have values going in order from "w46"-"w52" and then "w1"-"w52". The issue is that if the value in Cells(1, 12) is 5 for example, it will select the first row that has a 5 in it in the range (w50 in this case).

Is it possible to compare just the numbers in the cell (so not include the "w" with it still being present). If not, how do i make it so it picks up the exact values (So if the value in Cells(1, 12) is 5, then it goes to right 5 instead of the first 5 in the range)

Answer 1

You can "cheat" a little, make the value of 5 as "W5" and then find a match for that in your range. Just add another variable, let's call it WeekNum2String and add the "W" as a prefix. Now you can search your range with Range("F2:F60").Find(WeekNum2String) .

Dim WeekNum2String As String

WeekNum2String = "W" & Cells(1, 12).Value

Note : you should use the Find method by defining a Range, then setting it to the Find result (and not with Activate ) .This method will allow you to trap errors if there is no Find .

Like this:

Dim FindRng As Range
Set FindRng = Range("F2:F60").Find(WeekNum2String)

If Not FindRng Is Nothing Then
    U = FindRng.Row
Else
    MsgBox "Week number " & Cells(1, 12).Value & " not found in Range"
End If

Answer 2

I suggest you use an optional argument to the find method, which allows you to insist that the entire cell is matched, and not just some subset of the text inside. You want to use the LookAt argument, and set it to xlWhole. Now nothing will be found for "5", because no cell will match "5" entirely. Cells containing "w5" aren't a match with LookAt:=xlWhole. I know, the naming of arguments is not at all intuitive...

Furthermore, life would be much easier if you simply used a string "w5" in your search. An alternative would be to strip the w's out of the cells in the find (search) range. This can be done with the split method.

Answer 3

use xlWhole value for lookat argument of Find() method:

Range("F2:F60").Find("W" & WeekNum2, lookat:=xlWhole, LookIn:=xlValues).Activate
U = ActiveCell.Row

furthermore you can avoid Select and directly go like follows:

U = Range("F2:F60").Find("W" & WeekNum2, lookat:=xlWhole, LookIn:=xlValues).Row