Windows批处理文件-多选

Question

I had a question regarding batch file. I have a batch script which runs on "right click" of a directory.

But If i have selected MULTIPLE directories, the script executes for each selection one by one.. Is it possible to perhaps integrate this in a way that the script executes for all selections ONCE ? Or perhaps I get the list of all selections in the batch script? (perhaps a change in registry? )

Thanks Saad

Answer 1

Yes, it's possible. Paste a shortcut of your script to the shell:sendto folder . Then:

• "right click" a single item or multiple selection;
• navigate to "Send to" submenu;
• click on your script shortcut.

Unfortunately, described method works not only for directories (folders): it accepts file names as well. You need to add some tests about validity of supplied names into your script.

Below is a script used for testing (it distinguishes file / folder / unknown individually):

@echo OFF
SETLOCAL enableextensions disabledelayedexpansion
echo(
echo before any shift
echo "%~nx0" [%~1] [%~2] [%~3] [%~4]
echo   all %%* = %*
echo(
set /A "ii=0"
:loopfor
  if "%~1"=="" goto :loopend
  set /A "ii+=1"
  If exist "%~1\*" (
      echo folder  %%%ii% = %1  
  ) else (
      If exist "%~1" (
          echo   file  %%%ii% = %1
      ) else (
          echo unknown %%%ii% = %1
      )
  )
  SHIFT
  goto :loopfor
:loopend
  SHIFT
echo(
echo after all shifts: %ii% parameter^(s^)
echo "%~0" [%~1] [%~2] [%~3] [%~4]
echo   all %%* = %*
ENDLOCAL
pause>NUL
goto :eof