如果条件不起作用，索引与数组公式匹配吗？

Question

I have 2 worksheets in an excel workbook. Sheet 'Data' and sheet 'Home'.

Data:

Column B (Lookup Value)          Column C (Criteria)         Column D (Criteria)      COLUMN E (Criteria)         Column F
329115121601                     3291                        5555                     15/12/16                    50 <---- Week Number from date

On my other sheet, 'Home' i am trying to look up the number from column B using an index match (array formula) where the values match those in column C and D and E or F.

Home:

Column H      Column I      Column J                   Column K
3291          5555          15/12/2016 or Week 50      {=IFERROR(INDEX(Data!$B:$B,MATCH(1,(Home!$H10=Data!$C:$C)*(Home!$I10=Data!$D:$D)*(IF(Home!$J10<55,Home!$J10,WEEKNUM(Home!$J10))=Data!$F:$F),0)),"No Po Found")}

I am nesting an if statement within my index match to try and allow the user to enter either the specific date or the week number of that date. The user should be able to enter either week number or a specific date and get a result.

For some reason, this formula works if the user enters a week number, but not if they enter a specific date. Please can someone show me where i am going wrong? Thanks

EDIT

I am getting my date '151216' from a string in column B. like so:

Data: (Formula View)

Column B            Column E (UK Date Formatted as DD/MM/YYYY)              Column F (Week Num) 
329115121601       =DATE("20"&MID(B8,9,2),MID(B8,7,2),MID(B8,5,2))         =IF(F8<>"",WEEKNUM(F8,21),"") 

Data: (Value View)

Column B            Column E (UK Date Formatted as DD/MM/YYYY)     Column F (Week Num) 
329115121601        15/12/2016                                     50

My week number formula in column F produces a value error when the date is entered with this formula as 15/12/2016. No week number is produced. Likewise, if the date is typed in as 15/12/2016 i get a value error in column F and no week number is produced.

However, If i enter my date in column E as 12/15/2016 manually, without the formula this renders as 15/12/2016 and a week number of 50 is shown in column F.

Then on my home sheet, column J is date formated DD/MM/YYYY for UK and i must enter the date in column j as 12/15/2016 which will render as 15/12/2016 and then this way i get a result. So there must be a problem with the formula in column E i suppose?

users will be entering the date in column J on Home sheet as 15/12/2016 not 12/15/2016. So What can i do to fix this?

Answer 1

It seems you need to have the right return_type for the Gregorian Calendar and ISO 8601 standard. Included in Excel 2010.
WEEKNUM(Home!$J10,21)

{=IFERROR(INDEX(Data!$B:$B,MATCH(1,(Home!$H10=Data!$C:$C)*(Home!$I10=Data!$D:$D)*(IF(Home!$J10<55,Home!$J10,WEEKNUM(Home!$J10,21))=Data!$F:$F),0)),"No Po Found")}

Strange for me the function seems to work fine. Did you check if the seperated WEEKNUM(Home!$J10,21) function returns the correct weeknumber.
Because WEEKNUM(Home!$J10) without return_type=21 the weeknumber produced is 51 instead of 50 which we want.

Also try this one.

{=IFERROR(INDEX(Data!$B:$B,MATCH(1,(Home!$H10=Data!$C:$C)*(Home!$I10=Data!$D:$D)*(IF(Home!$J10<55,Home!$J10,ISOWEEKNUM(Home!$J10))=Data!$F:$F),0)),"No Po Found")}

It matches the data correctly even if the data is US format and input in UK format.