Haskell：使用parseFileExif时无法将类型“ IO”与“ []”匹配

Question

Playing around with Haskell I'm trying to build a script that takes paths to image files and outputs the EXIF creation date of these files. The photoProcess function of the following module is called from the executable:

module Lib
    ( photoProcess
    ) where

import Graphics.HsExif
import Data.Time.Format
import Data.Time.LocalTime
import Data.Map

photoProcess :: [FilePath] -> IO ()
photoProcess arguments = putStrLn ("photoProcess: " ++ (unwords (getDateStringFromFileList arguments)))

getDateStringFromFileList :: [FilePath] -> [String]
getDateStringFromFileList = fmap getDateStringFromFile

getDateStringFromFile :: FilePath -> String
getDateStringFromFile filePath = do
  exifData <- parseFileExif filePath
  exifToString exifData

exifToString :: Either String (Map ExifTag ExifValue) -> String
exifToString (Left message) = message
exifToString (Right exifMap) = timeToString exifMap

timeToString :: Map ExifTag ExifValue -> String
timeToString exifMap = case getDateTimeOriginal exifMap of
  Just localTime -> formatTime defaultTimeLocale "%m/%d/%Y %I:%M %p" localTime
  Nothing -> "Nothing"

I know the script has several errors but I do not know how to find or fix them. stack build says:

• Couldn't match type ‘IO’ with ‘[]’
  Expected type: [Either String (Map ExifTag ExifValue)]
    Actual type: IO (Either String (Map ExifTag ExifValue))
• In a stmt of a 'do' block: exifData <- parseFileExif filePath
  In the expression:
    do { exifData <- parseFileExif filePath;
         exifToString exifData }
  In an equation for ‘getDateStringFromFile’:
      getDateStringFromFile filePath
        = do { exifData <- parseFileExif filePath;
               exifToString exifData }

The main problem seems to be

exifData <- parseFileExif filePath

Where is the list from the error message coming from? Why expect a list?

Testing the types in GHCI I get:

Prelude Graphics.HsExif> :t parseFileExif path
parseFileExif path
  :: IO
       (Either
          String (containers-0.5.7.1:Data.Map.Base.Map ExifTag ExifValue))
Prelude Graphics.HsExif> test <- parseFileExif path
Prelude Graphics.HsExif> :t test
test
  :: Either
       String (containers-0.5.7.1:Data.Map.Base.Map ExifTag ExifValue)

What am I missing here?

Answer 1

Your type signature says

getDateStringFromFile :: FilePath -> String

String is [Char] , which is a list.

getDateStringFromFile filePath = do

Therefore here the compiler expects all statements of this do block to have a list type.

Did you mean IO String ?

In that case exifToString exifData has the wrong type (no IO ), so you'd have to use return :

    return (exifToString exifData)

Answer 2

The issue is that getDateStringFromFile implementation is wrong, it should be something like:

getDateStringFromFile :: FilePath -> IO String
getDateStringFromFile filePath = do
  exifData <- parseFileExif filePath
  return $ exifToString exifData

At that point you could use the new getDateStringFromFile like this:

photoProcess :: [FilePath] -> IO ()
photoProcess arguments = do
  dateStrings <- getDateStringFromFileList arguments
  putStrLn ("photoProcess: " ++ (unwords dateStrings))

getDateStringFromFileList :: [FilePath] -> IO [String]
getDateStringFromFileList = mapM getDateStringFromFile