使用VBA删除Excel表中的空行

Question

I am trying to run a code to delete rows when the whole row has no data. I am currently using the code below, but it is deleting rows when even one cell is empty. I think I need to use intersect function but not sure how to as yet.

    Dim Rng As Range
    Dim MainSheet As Worksheet
    Set MainSheet = Sheet9
    MainSheet.Select

    On Error Resume Next
    Set Rng = MainSheet.Range("table3").SpecialCells(xlCellTypeBlanks)

    On Error Resume Next
    If Not Rng Is Nothing Then
       Rng.Delete Shift:=xlUp
    End If

Answer 1

It really all depends on what you mean by empty. I notice you're using xlCellTypeBlanks , so if you wanted to continue using that range property, then you could just compare the row's cell count with your SpecialCells cell count - if they match, then you have an 'empty' row.

There are many others ways of doing this, but I'm not aware of one which doesn't need to iterate each row in your table. Assuming you want to go the SpecialCells route, your iteration could be something like this:

Dim lo As ListObject
Dim lRow As ListRow
Dim rng As Range
Dim delRows As Collection

Set lo = Sheet1.ListObjects("Table1") 'change to your table name
On Error Resume Next
For Each lRow In lo.ListRows
    Set rng = Nothing
    Set rng = lRow.Range.SpecialCells(xlCellTypeBlanks)
    If Not rng Is Nothing Then
        If rng.Count = lRow.Range.Cells.Count Then
            If delRows Is Nothing Then
                Set delRows = New Collection
                delRows.Add lRow
            Else
                delRows.Add lRow, Before:=1
            End If
        End If
    End If
Next
On Error GoTo 0

If Not delRows Is Nothing Then
    For Each lRow In delRows
        lRow.Delete
    Next
End If

Answer 2

This is an alternate solution but should be considered in bad form since it effectively is altering the table count when it deletes a row. That's what amounts to bad programming practice.

Also if there are embedded blanks, it won't catch them. FYI I debugged using Sheet 1 instead of Sheet 9.

On the plus side it is more concise (for whatever that might be worth).

There are also VBA quirks that I don't fully appreciate. For example if you replace 'rng' in the find command with it's expression you'll get an error which I'd consider counter-intuitive unless someone knows why this should make sense.

Sub DeleteEmptyTableRows()
    Dim MainSheet As Worksheet
    Dim tabRng As Range, rng As Range, found As Range
    Dim row As Integer

    Set MainSheet = Sheet1
    MainSheet.Select

    Set tabRng = MainSheet.Range("table3")

    row = 1
    Do While row < tabRng.Rows.Count + 1:
      Set rng = tabRng.Rows(row)
      Set found = rng.Find("*", rng.Cells(, 1), SearchDirection:=xlPrevious)
      If found Is Nothing Then
         tabRng.Rows(row).EntireRow.Delete Shift:=xlUp
      Else
         row = row + 1
      End If
    Loop
End Sub

If you find any bugs, please let me know. Aside from not deleting entries that had blanks in them, it worked for whatever test data I used.