如何使用VBA更改Excel 2016中插入的图片（图标）的填充颜色

Question

Trying to add an 'Icon' (the one under the 'Insert' tab - not the conditional formatting ones) and change the fill color. Using the macro recorder results in the following code:

Sub Macro1()

    ActiveSheet.Pictures.Insert( _
        "https://hubblecontent.osi.office.net/ContentSVC/Content/Download?provider=MicrosoftIcon&fileName=Document.svg" _
    ).Select
    With Selection.ShapeRange.Fill
        .Visible = msoTrue
        .ForeColor.ObjectThemeColor = msoThemeColorAccent1 'this line throws the error
        .ForeColor.TintAndShade = 0
        .ForeColor.Brightness = -0.25
        .Transparency = 0
        .Solid
    End With

End Sub

Which was expected as it's the same code used to change the fill color of a 'Shape'. The problem is that the code doesn't actually work. It throws a run-time error The specified value is out of range .

While trying to figure it out I noticed when right clicking on the inserted 'Icon' that the 'Fill' option is disabled, which is obviously not the case when inserting manually. I suspect it has something to do with the 'Pictures' object as opposed to 'Shapes' and/or the need to pull the image info from the interwebs, but I'm no expert. That's why I'm here.

What I want to know is if this is doable through VBA or if I should just take a different route?

Answer 1

Try this:

Sub Change_Hand_to_Yellow()
Dim shp1 As Shape
Set shp1 = ActiveSheet.Shapes("Graphic 12")
With shp1
 .Fill.ForeColor.RGB = vbYellow
End With

End Sub

Answer 2

I realize this answers an old question. I ran into the same issue and obviously the recorded macro was not much of help, so I had to do some tinkering. This works for me...

Sub Macro1()

    Const path As String _
    = "https://hubblecontent.osi.office.net/ContentSVC/Content/Download?provider=MicrosoftIcon&fileName=Document.svg"

    Dim sheet As Worksheet
    Set sheet = ActiveSheet
    Dim insertedIcon As Shape
    Set insertedIcon = sheet.Shapes.AddPicture(path, msoFalse, msoTrue, 0, 0, -1, -1)

    With insertedIcon.Fill
        .Visible = msoTrue
        .ForeColor.ObjectThemeColor = msoThemeColorAccent1
        .ForeColor.TintAndShade = 0
        .ForeColor.Brightness = -0.25
        .Transparency = 0
        .Solid
    End With

End Sub