vb.net-如何多次使用SUB打开同一表格

Question

You probably think this is a duplicate of other questions about this. But it isn't

I have seen several different questions about this but none of them answer this.

I would to open a form multiple times USING A SUB. Where I pass in a Form and it creates a new instance of this form. However I keep having problems with the Form being disposed if I run it twice

This is the sub that does not work:

Public Shared Sub OpenProgram(ByRef formToOpen As Form)
    Dim newApp As Form
    newApp = formToOpen
    Try
        newApp.Show()
        newApp.BringToFront()
    Catch ex As Exception
        MsgBox("Unable to open program :(")
    End Try
End Sub

I have also tried Dim newApp As New Form and
Dim newApp As New formToOpen however none of these work

I only have the problem if I try and run the sub, then close the form, then run the sub again.

The error I get is:

Can not access a disposed object
Object Name: 'shop'

shop is just a form

Thanks in advance

Answer 1

Option one, with generics :

Public Function OpenProgram(Of F As {Form, New})(ByVal ThisOne As F) As F
    Return New F()
End Function

Option two, without generics :

Public Function OpenProgram(ByVal ThisOne As Form) As Form
    Return CType(Activator.CreateInstance(ThisOne.GetType()), Form)
End Function

---

Usage:

Dim newApp As Form = OpenProgram(shop)
newApp.Show

Answer 2

Given a master form with 2 buttons and the following code, and two other forms, the buttons can be clicked repeatedly to open multiples of the forms, and closing them has no effect on opening more.

Public Class MasterForm
    Private Sub btnOpenForm1_Click(sender As Object, e As EventArgs) Handles btnOpenForm1.Click
        ShowForm(New Form1)
    End Sub

    Private Sub btnOpenForm2_Click(sender As Object, e As EventArgs) Handles btnOpenForm2.Click
        ShowForm(New Form2)
    End Sub

    Private Sub ShowForm(WhichForm As Form)
        With WhichForm
            .Show()
            .BringToFront()
        End With
    End Sub
End Class

Answer 3

 Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Try
            Dim x As String = Application.ExecutablePath

            Process.Start(x)

        Catch ex As Exception
            MsgBox("Executable path does not exist", MsgBoxStyle.Information, "New Window")
        End Try
    End Sub

Answer 4

Your "closed " form is not closed until you dispose of it, it is just not shown. You need to loop through your forms and show the form that you want to view again. You will probably use something like this -

Private Sub cmdOpenForm_Click(sender As Object, e As EventArgs) Handles  cmdOpenForm.Click

    Dim frmCollection = System.Windows.Forms.Application.OpenForms
    If frmCollection.OfType(Of frmShop).Any Then
        frmCollection.Item("frmShop").Activate()
    Else
        Dim frmShop As New frmShop
        frmShop.Show()
    End If

    Me.Close()
    Me.Dispose()
End Sub

The close and dispose part is pointing to the form you are currently in. As forms are objects you need to activate them again for them to be used or you need to recreate them again to show a new instance of that form.

Hope this is what you were looking for.