Excel VBA：如果列A在字符串中包含数字，则删除行

Question

I am trying to write a formula in Excel to delete an entire row if the cell in Column C contains a number within the cell, except the number 0.

eg

A2 - delete
A0 - don't delete
M - don't delete
ABC6 - delete
NN - don't delete


Sub FindInvalid()
    Dim Firstrow As Long
    Dim Lastrow As Long
    Dim Lrow As Long
    Dim CalcMode As Long
    Dim ViewMode As Long
    Dim JEType As Variant

    InvalidCharacters= Array(1, 2, 3, 4, 5, 6, 7, 8, 9)

    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
    End With

    With ActiveSheet

        .Select

        ViewMode = ActiveWindow.View
        ActiveWindow.View = xlNormalView

        .DisplayPageBreaks = False

        Firstrow = .UsedRange.Cells(1).Row
        Lastrow = .UsedRange.Rows(.UsedRange.Rows.Count).Row

        For Lrow = Lastrow To Firstrow Step -1

            With .Cells(Lrow, "C")

                If Not IsError(.Value) Then
                Debug.Print (.Value)

                    If IsInArray(.Value, InvalidCharacters) = True Then .EntireRow.Delete
                    'This will delete each row where Column C contains a number

                End If

            End With

        Next Lrow

    End With

    ActiveWindow.View = ViewMode
    With Application
        .ScreenUpdating = True
        .Calculation = CalcMode
    End With

End Sub

The above works great, but I'm struggling with the below.

Function IsInArray(StringToBeFound As String, arr As Variant) As Boolean
  IsInArray = Not IsError(Application.Find(StringToBeFound, "contains", arr, 0))

End Function

Any help would be greatly appreciated.

Answer 1

You are only checking a single cell at a time to see if it contains certain digits.

Instead of the IsInArray function, perhaps:

     With .Cells(Lrow, "C")

            If Not IsError(.Value) Then
            Debug.Print (.Value)

                If .Value Like "*[1-9]*" Then .EntireRow.Delete
                'This will delete each row where Column C contains a number

            End If

        End With

EDIT: For large worksheets, this may not be the most efficient method. One possibility would be to use the Advanced Filter.

For the Advanced Filter, you can use a formula for the criteria:

  =NOT(OR(ISNUMBER(FIND({1,2,3,4,5,6,7,8,9},C9))))

You'll probably want to copy the results to another location.

A VBA routine that might work faster:

Algorithm

• Read Column C into a variant array
• process each item to see if it meets the criteria to be deleted
• Collect the row number for each item to be deleted
• Use the Union method to create a range to be deleted
• Delete the range

---

Option Explicit
Sub delNumRows()
    Dim V As Variant
    Dim COL As Collection
    Dim I As Long
    Dim R As Range

V = Range(Cells(1, 3), Cells(Rows.Count, 3).End(xlUp))

Set COL = New Collection
For I = 1 To UBound(V)
    If V(I, 1) Like "*[1-9]*" Then COL.Add I
Next I

For Each V In COL
    If R Is Nothing Then
        Set R = Cells(V, 1).EntireRow
    Else
        Set R = Union(R, Cells(V, 1).EntireRow)
    End If
Next V

R.Delete

End Sub

---

Answer 2

standing the "structrure" of your array to be searched in, you could use this:

Function IsInArray(StringToBeFound As String, arr As Variant) As Boolean
    IsInArray = InStr("|" & Join(arr, "|") & "|", "|" & StringToBeFound & "|") > 0
End Function