Delphi Firedac master详细信息多个

Question

i have 2 table in relation master-details displayed in 2 tdbgrid. Now I would like to display each field on the rows of the table details in a Tedit controll, but now i view only the first row of detail in my first group of tedit.

enter image description here

Answer 1

If this is a VCL project (and not a FireMonkey one), you can do this very simply.

• Place a TDBCtrlGrid on your form and set its DataSource for the detail dataset.

• In the IDE, the DBCtrlGrid will display a vertical series of panels, one colored solid gray and the others striped. Place db-aware controls like TDBEdits on the solid gray panel, set their DataField properties, then compile and run. The DBCtrlGrid has an Orientation property which you can set to vertical or horizontal, according to your preference.

You should see that at run-time, the DBCtrlGrid populates with as many instances of the panel and the db-aware components it contains as there are detail records, up to the number specified by the DBCtrlGrid's RowCount property. If you want to ensure that there are enough copies of the panel, you could try setting the RowCount value to the RecordCount' of the detail dataset in the AfterScroll` event of the master dataset.

On the other hand, if it is a FireMonkey (FMX) project so you need to use LiveBindings (which have no TDBCtrlGrids), it may be possible to do this in a similar manner as you would set up controls to display the fields of the Master dataset, but I've never tried.

The following minimal VCL project code extract shows the use of a DBCtrlGrid;

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ExtCtrls, DBCtrls, Grids, DBGrids, DB, DBClient,
  dbcgrids, Mask;

type
  TForm1 = class(TForm)
    cdsMaster: TClientDataSet;
    cdsDetail: TClientDataSet;
    dsMaster: TDataSource;
    dsDetail: TDataSource;
    gMaster: TDBGrid;
    dbnavMaster: TDBNavigator;
    gDetail: TDBGrid;
    dbnavDetail: TDBNavigator;
    DBCtrlGrid1: TDBCtrlGrid;
    DBEdit1: TDBEdit;  // placed in DBCtrlGrid1
    DBEdit2: TDBEdit;  // placed in DBCtrlGrid1
    procedure cdsMasterAfterScroll(DataSet: TDataSet);
    procedure FormCreate(Sender: TObject);
  private
  public
  end;

[...]

procedure TForm1.FormCreate(Sender: TObject);
var
  i,
  j : Integer;
  Field : TIntegerField;
begin
  DBEdit1.DataField := 'MasterID';
  DBEdit2.DataField := 'DetailID';

  Field := TIntegerField.Create(Self);
  Field.FieldName := 'MasterID';
  Field.DataSet := cdsMaster;
  cdsMaster.CreateDataSet;

  Field := TIntegerField.Create(Self);
  Field.FieldName := 'DetailID';
  Field.DataSet := cdsDetail;
  Field := TIntegerField.Create(Self);
  Field.FieldName := 'MasterID';
  Field.DataSet := cdsDetail;

  cdsDetail.MasterSource := dsMaster;
  cdsDetail.MasterFields := 'MasterID';
  cdsDetail.IndexFieldNames := 'MasterID;DetailID';
  cdsDetail.CreateDataSet;

  for i := 1 to 10 do begin
    cdsMaster.InsertRecord([i]);
    for j := 1 to i do
      cdsDetail.InsertRecord([j, i]);
  end;
  cdsMaster.First;
end;

procedure TForm1.cdsMasterAfterScroll(DataSet: TDataSet);
begin
  cdsDetail.DisableControls;
  try
    DBCtrlGrid1.RowCount := cdsDetail.RecordCount;
  finally
    cdsDetail.EnableControls;
  end;
end;

Answer 2

只需将TDBEdit放在窗体上，然后设置其Datafield属性和详细信息表的Datasource属性。