Perl存在无法正常工作

Question

I'm trying to count the emails occurrences in a file. But it's seems that exists is not working as expected. When i found a new email the code should print not in hash Else it should print in hash.

But "in hash" is never printed

How can i count the email ocurrences?

use strict;
use 5.014;
open(FCG,"<","pruecorreos") or die "No se puede \n";
my %correos = ();
my $i = 0;
while (<FCG>) {
    chomp;
    print "\nAnalizando: $_";

    if ( my @m = $_ =~/(\w+@\w+\.\w+)(\.\w+)*/ ) {

        my $lel = join("",@m);
        print "lel es [$lel]";

        if ( exists $correos{$lel} ) {
            print "\n$lel  in hash";
            $correos{$lel}=1;
        }
        else {
            print "\n$lel NOT in hash";
            $correos{$lel}++;
        }
    }
}

Answer 1

You are mistaken. If I run your code against this data file

pruecorreos

aaa@mail.example.com
aaa@mail.example.com

then I get this output

Analizando: aaa@mail.example.comlel es [aaa@mail.example.com]
aaa@mail.example.com NOT in hash
Analizando: aaa@mail.example.comlel es [aaa@mail.example.com]
aaa@mail.example.com  in hash[Finished in 0.1s]

which shows that duplicates are being detected correctly

However, the errors that I pointed out in my comment need to be fixed, and I would do it like this

use strict;
use warnings 'all';

open my $fcg, '<', 'pruecorreos' or die "No se puede: $!";

my %correos;

while ( <$fcg> ) {

    chomp;

    print "Analizando: $_\n";

    next unless my ($lel) = /( \w+ \@ \w+ (?: \. \w+ )+  )/x;

    print "lel es [$lel]\n";

    print $correos{$lel}++ ? "$lel is in hash\n" : "$lel is NOT in hash\n";

    print "\n";
}

output

Analizando: aaa@mail.example.com
lel es [aaa@mail.example.com]
aaa@mail.example.com is NOT in hash

Analizando: aaa@mail.example.com
lel es [aaa@mail.example.com]
aaa@mail.example.com is in hash