Excel VBA重新订购电子邮件内容

Question

I have compiled the following code in VBA to send out an email. I want to send a simple message with a Range of cells in a table format. The code below works. But the output is flipped. I want the message text on top and the table on the bottom. (Please see image attached). Any time I try to move anything around I get a "424 Object Required" error.

Please advise.

Sub SendEmail()
Dim msg As String
Set mailApp = CreateObject("Outlook.Application")
Set mail = mailApp.createitem(olMailItem)

msg = "Good Morning Team, " & "<br><br>" _
        & "Here is this week's Coffee Talk groups. Enjoy!" & "<br><br>"

With mail
    .To = "someone@gmail.com"
    .Subject = "Coffee Talk " & Date
    .HTMLBody = msg
End With
mail.display

Set wEditor = mailApp.ActiveInspector.wordEditor
ThisWorkbook.Sheets("Groups").Range("A1:E4").Copy
wEditor.Application.Selection.Paste

End Sub

Answer 1

There is a Range to HTML function made by Ron de Bruin that would help you with your issue. I have amended your code for his function to work:

Sub SendEmail()

Dim msg As String
Set mailApp = CreateObject("Outlook.Application")
Set mail = mailApp.createitem(olMailItem)
Dim rng As Range

msg = "Good Morning Team, " & "<br><br>" _
        & "Here is this week's Coffee Talk groups. Enjoy!" & "<br>"

Set rng = Sheets("Groups").Range("A1:E4").SpecialCells(xlCellTypeVisible)

With mail
    .To = "someone@gmail.com"
    .Subject = "Coffee Talk " & Date
    .HTMLBody = msg & "<br>" & RangetoHTML(rng)
    .display
End With

End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function