编译webkit / webview应用时出错-Vala / GTK

Question

I am trying to build my first webkit based app using Vala and GTK. I'm very new to these to languages and the process of compiling them so any help would be great.

This is the error I receive:

/home/elementary/GTKProjects/Fookbase/src/fookbase_main.vala:2.7-2.12: error: The namespace name `WebKit' could not be found using WebKit;

/home/elementary/GTKProjects/Fookbase/src/fookbase_main.vala:13.13-13.19: error: The type name `WebView' could not be found private WebView web_view;

This is my code:

using Gtk;
using WebKit;

public class Fookbase : Window {

private const string TITLE = "Fookbase";
private const string HOME_URL = "http://fookbase.com";
private const string DEFAULT_PROTOCOL = "http";

private Regex protocol_regex;

private Entry url_bar;
private WebView web_view;
private Label status_bar;
private ToolButton back_button;
private ToolButton forward_button;
private ToolButton reload_button;

public Fookbase () {
    this.title = Fookbase.TITLE;
    set_default_size (500, 800);

    try {
        this.protocol_regex = new Regex (".*://.*");
    } catch (RegexError e) {
        critical ("%s", e.message);
    }

    create_widgets ();
    connect_signals ();
    this.url_bar.grab_focus ();
}

private void create_widgets () {
    var toolbar = new Toolbar ();
    this.back_button = new ToolButton.from_stock (Stock.GO_BACK);
    this.forward_button = new ToolButton.from_stock (Stock.GO_FORWARD);
    this.reload_button = new ToolButton.from_stock (Stock.REFRESH);
    toolbar.add (this.back_button);
    toolbar.add (this.forward_button);
    toolbar.add (this.reload_button);
    this.web_view = new WebView ();
    var scrolled_window = new ScrolledWindow (null, null);
    scrolled_window.set_policy (PolicyType.AUTOMATIC, PolicyType.AUTOMATIC);
    scrolled_window.add (this.web_view);
    this.status_bar.xalign = 0;
    var vbox = new VBox (false, 0);
    vbox.pack_start (toolbar, false, true, 0);
    vbox.pack_start (this.url_bar, false, true, 0);
    vbox.add (scrolled_window);
    vbox.pack_start (this.status_bar, false, true, 0);
    add (vbox);
}

private void connect_signals () {
    this.destroy.connect (Gtk.main_quit);
    this.url_bar.activate.connect (on_activate);
    this.web_view.title_changed.connect ((source, frame, title) => {
        this.title = "%s - %s".printf (title, Fookbase.TITLE);
    }); 
    this.web_view.load_committed.connect ((source, frame) => {
        this.url_bar.text = frame.get_uri ();
        update_buttons ();
    });
    this.back_button.clicked.connect (this.web_view.go_back);
    this.forward_button.clicked.connect (this.web_view.go_forward);
    this.reload_button.clicked.connect (this.web_view.reload);
}

private void update_buttons () {
    this.back_button.sensitive = this.web_view.can_go_back ();
    this.forward_button.sensitive = this.web_view.can_go_forward ();
}

private void on_activate () {
    var url = this.url_bar.text;
    if (!this.protocol_regex.match (url)) {
        url = "%s://%s".printf (Fookbase.DEFAULT_PROTOCOL, url);
    }
    this.web_view.open (url);
}

public void start () {
    show_all ();
    this.web_view.open (Fookbase.HOME_URL);
}

public static int main (string[] args) {
    Gtk.init (ref args);

    var browser = new Fookbase ();
    browser.start ();

    Gtk.main ();

    return 0;
  }
}

Answer 1

In order to use a library in Vala, you need to tell the compiler about it. Just saying "using WebKit" in the code isn't enough. You do this by passing the --pkg flag (with the desired value) to valac .

The name of the package for almost all bindings matches the pkg-config name so the Vala compiler can automatically determine the correct flags to pass to the C compiler and the linker. To see which packages are available from Vala, you can look in the /usr/share/vala/vapi and /usr/share/vala-x.yz/vapi directories (the latter being specific to the version of valac you're using). Valadoc.org also has the names for a lot of packages. I'm not sure what your reference was when you wrote your code, but generally they will tell you what package you're looking at.

For WebKit, if you're writing new software you probably want to use either webkit2gtk-4.0 or webkit2gtk-web-extension-4.0 , which are the packages which link against gtk+-3.0.

So, something like

valac --pkg webkit2gtk-4.0 ... your-file.vala