在Excel VBA中基于FALSE值删除行（运行时错误91）

Question

I have a spreadsheet that needs to have rows deleted based off a "FALSE" value. Researching the net, I found some code from this site:

https://www.extendoffice.com/documents/excel/815-excel-remove-rows-based-on-cell-value.html

Sub DeleteRows()

    Dim rng As Range
    Dim InputRng As Range
    Dim DeleteRng As Range
    Dim DeleteStr As String
    xTitleId = "Delete Based on Cell Value"
Set InputRng = Application.Selection
Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
DeleteStr = Application.InputBox("Delete Text", xTitleId, Type:=2)
For Each rng In InputRng
If rng.Value = DeleteStr Then
    If DeleteRng Is Nothing Then
        Set DeleteRng = rng
    Else
        Set DeleteRng = Application.Union(DeleteRng, rng)
    End If
End If
Next
DeleteRng.EntireRow.Delete '<----- *highlighted error*

End Sub

Upon execution of the macro, I get the "Runtime 91 object variable not set" error.

I am aware that I need to set "DeleteRng" to an object, but I am not sure what. I am new to VBA and it could be something minor I am overlooking.

Answer 1

You need to check first that DeleteRng contains something

Sub DeleteRows()

Dim rng As Range
Dim InputRng As Range
Dim DeleteRng As Range
Dim DeleteStr As String
Dim xTitleId As String

xTitleId = "Delete Based on Cell Value"
Set InputRng = Application.Selection
Set InputRng = Application.InputBox("Range :", xTitleId, InputRng.Address, Type:=8)
DeleteStr = Application.InputBox("Delete Text", xTitleId, Type:=2)

For Each rng In InputRng
    If rng.Value = DeleteStr Then
        If DeleteRng Is Nothing Then
            Set DeleteRng = rng
        Else
            Set DeleteRng = Application.Union(DeleteRng, rng)
        End If
    End If
Next

If Not DeleteRng Is Nothing Then DeleteRng.EntireRow.Delete '<----- *highlighted error*

End Sub

Answer 2

The code works just fine for me when I test it, but I have a feeling I know what is happening when you are running it. Chances are, it isnt finding the text you are inputting into your box.

Try putting a breakpoint at "DeleteRng.EntireRow.Delete". You can do this by clicking in the thin grey bar of the window to the left of your code.

I would also edit your code from:

DeleteRng.EntireRow.Delete '<----- *highlighted error*

to

If Not DeleteRng Is Nothing Then
    DeleteRng.EntireRow.Delete '<----- *highlighted error*
Else
    msgbox "No rows found!"
End If

This will provide the inverse of your object. If the object is set to something, then the inverse is nothing. This will prevent your code from raising an error when an object isnt set. You can remove the else statement as well, but with the else statement in there it will tell you if nothing is set.

Answer 3

(Posted on behalf of the OP) .

I figured out my mistake! With a little help and modification to the code, as well as a suggestion, I realized that the value I was typing in was different from the returned value because it was case-sensitive.

Column B had the "FALSE" value displayed in all caps, but the immediate window showed the value was actually "False". I searched correctly with "False" and it worked perfectly!

I also changed the error part to:

If Not DeleteRng Is Nothing Then DeleteRng.EntireRow.Delete