单例/里程碑元素的XSLT转换

Question

I'm looking for an elegant XSLT 1.0 or 2.0 solution to the following transform problem. I've simplified the markup below so "a" is the start milestone element, and "b" is the end milestone element. Everything between the "a" and the "b" must be wrapped with element "c".

Input:

<doc>
<line>Text text <a/>text<b/></line>
<line>Text <a/>text text</line>
<line>Text<b/> text <a/>text</line>
<line>Text text text</line>
<line>Text text<b/> text</line>
</doc>

Output:

<doc>
<line>Text text <c>text</c></line>
<line>Text <c>text text</c></line>
<line><c>Text</c> text <c>text</c></line>
<line><c>Text text text</c></line>
<line><c>Text text</c> text</line>
</doc>

In the real-world case, there are at least 5 variations each of the a/b/c elements to cater for. There are also tens of thousands of lines, many of which do not contain a/b or their variations. The real-world case also has a "sec" element wrapping groups of lines, where the a/b behaviour still needs to work through.

Our initial solution involved the use of preceding::* but this obviously brings significant performance issues for large XML documents, so is not an acceptable solution.

Answer 1

Thanks to Michaely Kay for the inspiration. Forgetting for a moment about the mechanics of wrapping the <c>..</c> elements, the correct algorithm as implemented in XSLT 3.0 appears to be:

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" />

<xsl:template match="/doc" >
    <xsl:copy>
        <xsl:iterate select="line">
            <xsl:param name="state">b</xsl:param>
            <xsl:variable name="lastState" select="local-name((a|b)[last()])"/>
            <xsl:variable name="nextState">
                <xsl:choose>
                    <xsl:when test="$lastState">
                        <xsl:value-of select="$lastState"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$state"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:variable>

            <xsl:copy>
                <xsl:if test="$state = 'a'"><startC/></xsl:if>
                <xsl:apply-templates/>
                <xsl:if test="$nextState = 'a'"><endC/></xsl:if>                    
            </xsl:copy>

            <xsl:next-iteration>
                <xsl:with-param name="state" select="$nextState"/>
            </xsl:next-iteration>                                        
        </xsl:iterate>
    </xsl:copy>
</xsl:template>

<xsl:template match="a">
    <startC/>
</xsl:template>

<xsl:template match="b">
    <endC/>
</xsl:template>

Giving output:

<doc>
    <line>Text text <startC/>text<endC/></line>
    <line>Text <startC/>text text<endC/></line>
    <line><startC/>Text<endC/> text <startC/>text<endC/></line>
    <line><startC/>Text text text<endC/></line>
    <line><startC/>Text text<endC/> text</line>
</doc>