运行时错误'424'-Excel中的VBA

Question

I'm very very new to the VBA world.

I want to select 2 ranges from 2 worksheets in different workbooks.

But I got that message in my script. please help

Sub CommandButton1_Click()

Application.ScreenUpdating = False

Dim wb1 As Workbook, wb2 As Workbook
Dim ws1 As Worksheet, ws2 As Worksheet
Dim rng1 As Range, rng2 As Range

Set wb1 = Workbooks("TEMPLATE.xls")
Set ws1 = Sheets("macro")
Set rng1 = Range(Range("C3"), Range("C3").End(xlDown)).Select

Set wb2 = Workbooks("booking.xlsx")
Set ws2 = Sheets("ABC")
Set rng2 = Range(Range("L3"), Range("L3").End(xlDown)).Select

End Sub

Answer 1

I saw multiple problems in your code. First of all, when you select a worksheet through the Sheets() property, it will look among the sheets of the currently activated (aka ActiveWorkbook ) workbook by default. Same goes for selecting a Range of cells (Range() function), looks in the active worksheet. So you have to be more specific in this case:

Dim wb1 As Workbook, wb2 As Workbook
Dim ws1 As Worksheet, ws2 As Worksheet
Dim rng1 As Range, rng2 As Range

Set wb1 = Workbooks("TEMPLATE.xls")
Set ws1 = wb1.Sheets("macro")
Set rng1 = ws1.Range(Range("C3"), Range("C3").End(xlDown))
rng1.Select

Set wb2 = Workbooks("booking.xlsx")
Set ws2 = wb2.Sheets("ABC")
Set rng2 = ws2.Range(Range("L3"), Range("L3").End(xlDown))
rng2.Select

And also notice that the Select function only highlights the returned cell, but it does not return the value itself. So instead of highlighting the cells, I just return it ---> removed the .Select parts.

Although notice that you can't have two simultaneously highlighted cells across workbooks, but by using this code you can always access the two cells through the rng1 and rng2 variables

If you found my answer the most helpful, please reward me with a green tick ;)

Answer 2

Tried and tested throughout.

I tried to replicate your error by creating books and sheets as alluded to in your code. Added a CommandButton1 to the macro sheet and inserted your code into its Click event handler.

Attempting to step through the code did select the range on macro sheet but threw Error 424 (Object required) and code execution terminated without highlighting anything in the IDE.

Changing:

Set rng1 = Range(Range("C3"), Range("C3").End(xlDown)).Select

to

Set rng1 = Range(Range("C3"), Range("C3").End(xlDown))
rng1.Select

got rid of the error but next step through gave an Error 9 (Subscript out of range) on Set ws2 = Sheets("ABC") . This is because TEMPLATE.xls was still the active workbook.

Changing Set ws2 = Sheets("ABC") to Set ws2 = wb2.Sheets("ABC") cleared this error but then got Error 424 again due to .Select on the Set Rng2 line. Also, cells in column L on macro sheet were selected.

Changing:

Set rng2 = Range(Range("L3"), Range("L3").End(xlDown)).Select

to:

Set rng2 = Range(Range("L3"), Range("L3").End(xlDown))
rng2.Select

got rid of that error but cells in macros sheet were still selected.

To fix that I changed:

Set rng2 = Range(Range("L3"), Range("L3").End(xlDown))
rng2.Select

to:

With ws2
    Set rng2 = Range(.Range("L3"), .Range("L3").End(xlDown))
End With
rng2.Select

I thought that had solved it but then got an `Error 1004 (Select method of Range class failed) which I could only overcome by activating bookings.xlsx!

You need to explicitly declare your Sheets and Ranges:

Sub CommandButton1_Click()
Dim wb1 As Workbook, wb2 As Workbook
Dim ws1 As Worksheet, ws2 As Worksheet
Dim rng1 As Range, rng2 As Range

    Application.ScreenUpdating = False
    Set wb1 = Workbooks("TEMPLATE.xls")
    Set ws1 = wb1.Sheets("macro")
    With ws1
        Set rng1 = .Range(.Range("C3"), .Range("C3").End(xlDown))
        rng1.Select
    End With

    Set wb2 = Workbooks("booking.xlsx")
    wb2.Activate
    Set ws2 = wb2.Sheets("ABC")
    With ws2
        Set rng2 = .Range(.Range("L3"), .Range("L3").End(xlDown))
    End With
    rng2.Select
    wb1.Activate
    Application.ScreenUpdating = True
End Sub

Answer 3

You can't Select 2 Range s from 2 workbooks at the same time, you can do it one at a time (not sure why you need to Select the Range at all).

You need to fully qualify all your Worksheets and Range s.

Set ws1 = Sheets("macro") - tries to look for a sheet named "macro" in ActiveWorkbook , and not wb1 .

Set rng1 = Range(Range("C3"), Range("C3").End(xlDown)).Select , will raise a run-time error. You can't Select when Set ting the Range. Also, this will set the range for Range. Also, this will set the range for ActiveSheet and not ws1`.

You need to first Set your Range : Set rng1 = ws1.Range(ws1.Range("C3"), ws1.Range("C3").End(xlDown)) , and only after (if really needed) to Select it: rng1.Select .

Code

Sub CommandButton1_Click()

Application.ScreenUpdating = False

Dim wb1 As Workbook, wb2 As Workbook
Dim ws1 As Worksheet, ws2 As Worksheet
Dim rng1 As Range, rng2 As Range
Dim UnRng As Range

Set wb1 = Workbooks("TEMPLATE.xls")
Set ws1 = wb1.Sheets("macro")
Set rng1 = ws1.Range(ws1.Range("C3"), ws1.Range("C3").End(xlDown))
rng1.Select

Set wb2 = Workbooks("booking.xlsx")
Set ws2 = wb2.Sheets("ABC")
Set rng2 = ws2.Range(ws2.Range("L3"), ws2.Range("L3").End(xlDown))
rng2.Select

End Sub