带有随机的T-SQL返回多行，期望其中的一行

Question

Consider the following T-SQL code (MS SQL Server 2014) that fetches a random row from a table variable:

DECLARE @priceClasses TABLE (
    RowIndex INT,
    PriceClassID NVARCHAR(MAX))
;

INSERT INTO @priceClasses VALUES
    (0, 'RETAIL')
    ,(1, 'WHOLESALE')
    ,(2, 'WHOLESALE2')
;

DECLARE @priceClassesCount AS INT;
SET @priceClassesCount = (SELECT COUNT(*) FROM @priceClasses);

SELECT 
    PriceClasses.RowIndex,
    PriceClasses.PriceClassID 
FROM
    @priceClasses AS PriceClasses
WHERE
    PriceClasses.RowIndex = ABS(CHECKSUM(NEWID())) % @priceClassesCount;

The last SELECT statement, for some reason, sometimes returns 0 rows, sometimes 1, 2, or 3 rows.

It does not make sense to me. The value of the column is unique, and ABS(CHECKSUM(NEWID())) % @priceClassesCount cannot be multi-valued, can it?

The issue disappears when I declare RowIndex INT NOT NULL PRIMARY KEY instead of just RowIndex INT . Any thoughts?

Answer 1

The WHERE clause is evaluated once per row. That is the beauty of NEWID() . Tragic beauty for your case.

If you are going to use this method, you might as well store the value in a variable:

DECLARE @priceClassesCount AS INT;
SET @priceClassesCount = (SELECT COUNT(*) FROM @priceClasses);
SET @RowIndex = 1 + (ABS(CHECKSUM(NEWID())) % @priceClassesCount)

SELECT pc.RowIndex, pc.PriceClassID 
FROM @priceClasses pc
WHERE pc.RowIndex = @RowIndex;

Hopefully, RowIndex has no gaps in it. That could be another reason why you are getting no rows.

Answer 2

To get one random row, you can do this

SELECT TOP 1
    PriceClasses.RowIndex,
    PriceClasses.PriceClassID 
FROM
    @priceClasses AS PriceClasses
ORDER BY
    NEWID();

Although @GordonLinoff is correct, the requirement has a simpler solution