尝试使用SUMPRODUCT根据另外两个条件识别唯一值？

Question

I am having some difficulty with this formula and I am hoping someone can help. I have searched extensively everywhere I can think of and can't find an answer pertaining directly to this issue. I have data in a spreadsheet table tracking employee assigned tasks and am focusing on three fields: the employee name (Employee Name), the date the employee was assigned a task (Employee Assigned Date) and the month and year the employee was assigned the task (Task Month Year).

I am trying to identify the unique assigned dates for a given employee in a given month/year. So in the example below, John Smith would return three unique dates for March 2017, since 03/05/2017 and 03/14/2017 repeat.

Employee Name        Employee Assigned Date        Task Month Year
Paul Martin          03/01/2017                    March 2017
James Smith          03/05/2017                    March 2017
James Smith          03/05/2017                    March 2017
James Smith          03/06/2017                    March 2017
James Smith          03/14/2017                    March 2017
James Smith          03/14/2017                    March 2017

The formula that I have come up with is as follows:

=SUMPRODUCT((Table2[Employee Name]=”James Smith”)*(Table2[Task Month Year]")=”March 2017”/(COUNTIF(Table2[Employee Assigned Date],Table2[Employee Assigned Date]&"")))

I have stripped out some pieces of the formula that convert month date to text, etc. so the issue is not around that. If I sumproduct the employee name and task month year section by itself, I get the correct answer for the total of James Smith's assigned tasks, five. If I remove the Employee Name piece I get the correct answer for unique dates in March 2017 for all employees, four.

Any help with this would be greatly appreciated, I'm assuming I am doing something stupid but I've been working on this for hours and can't seem to find the solution on my own.

Thank you!

Answer 1

You can do this by removing duplicates. If you need to retain the original data, then of course copy and paste it to a new tab first.

In the Data tab, select Remove Duplicates. Then in the pop-up box, make sure you select all 3 of your columns, presumably A, B and C from the way you laid it out above. This will make sure that duplicates matching all 3 columns will be removed, giving you a list of unique assignment dates per employee, per month/year combination.

Answer 2

COUNTIF will return the wrong values in your suggested formula because the name criteria isn't included in that part. One solution is to include the name criteria in an expanded COUNTIFS like this:

=SUM(IFERROR((Table2[Task Month Year]="March 2017")/(Table2[Employee Name]="James Smith")/COUNTIFS(Table2[Employee Assigned Date],Table2[Employee Assigned Date],Table2[Employee Name],"James Smith"),0))

confirm with CTRL+SHIFT+ENTER

.....or you can fall back on the old FREQUENCY approach, ie

=SUM(IF(FREQUENCY(IF(Table2[Task Month Year]="March 2017", IF(Table2[Employee Name]="James Smith",IF(Table2[Employee Assigned Date]<>"",MATCH(Table2[Employee Assigned Date],Table2[Employee Assigned Date],0)))),ROW(Table2[Employee Assigned Date])-MIN(ROW(Table2[Employee Assigned Date]))+1),1))

also confirm with CTRL+SHIFT+ENTER

Both should give the same answer