从Access VBA格式化Excel工作表

Question

I am outputting query results to Excel and want to format through my Access VBA syntax. Everytime I try to add in the formatting, I get errors. The one I am stuck on is

Unable to set the HorizontalAlignment property of the Range class

This is my syntax - what should be altered so that the syntax can modify Excel as needed?

Private Sub ToExcel_Click()
Dim lngColumn As Long
Dim xlx As Object, xlw As Object, xls As Object, xlc As Object
Dim dbs As DAO.Database
Dim rst As DAO.Recordset
Dim strPathFileName As String, strWorksheetName As String
Dim strRecordsetDataSource As String
Dim blnEXCEL As Boolean, blnHeaderRow As Boolean

    blnEXCEL = False

    strPathFileName = "Z:\House\Data.xlsx"
    strRecordsetDataSource = "Fa"
    blnHeaderRow = True
    On Error Resume Next
    Set xlx = GetObject(, "Excel.Application")
    If Err.Number <> 0 Then
          Set xlx = CreateObject("Excel.Application")
          blnEXCEL = True
    End If
    Err.Clear
    On Error GoTo 0
    xlx.Visible = True
    Set xlw = xlx.Workbooks.Add
    Set xls = xlw.Worksheets(1)
    xls.Name = "Cu"
    Set xlc = xls.Range("A1")
    Set dbs = CurrentDb()
    Set rst = dbs.OpenRecordset(strRecordsetDataSource, dbOpenDynaset, dbReadOnly)
    If rst.EOF = False And rst.BOF = False Then
          If blnHeaderRow = True Then
                For lngColumn = 0 To rst.Fields.Count - 1
                      xlc.Offset(0, lngColumn).Value = rst.Fields(lngColumn).Name
                Next lngColumn
                Set xlc = xlc.Offset(1, 0)
          End If
          xlc.CopyFromRecordset rst
    End If

    rst.Close
    Set rst = Nothing
    dbs.Close
    Set dbs = Nothing

    With xls
        .Range("A1:N1").Select
        .Columns("A:N").HorizontalAlignment = xlCenter
        .Columns("A:N").VerticalAlignment = xlBottom
        .Columns("A:N").WrapText = True
        .Columns("A:N").Orientation = 0
        .Columns("A:N").AddIndent = False
        .Columns("A:N").IndentLevel = 0
        .Columns("A:N").ShrinkToFit = False
        .Columns("A:N").ReadingOrder = xlContext
        .Columns("A:N").MergeCells = False
        .Columns("A:N").Selection.Font.Bold = True
        .Columns("N:N").ColumnWidth = 8.86
        .Columns("I:I").ColumnWidth = 8.86
        .Columns("C:G").Select
        .Selection.NumberFormat = "$#,##0"
        .Columns("J:J").Select
        .Selection.NumberFormat = "$#,##0"
        .Columns("K:M").Select
        .Selection.NumberFormat = "0%"
        .Range("P18").Select
        .Columns("A:A").EntireColumn.AutoFit
        .Columns("B:B").EntireColumn.AutoFit
        .Range("A1").Select
    End With

    Set xlc = Nothing
    Set xls = Nothing
    xlw.SaveAs strPathFileName
    xlw.Close False
    Set xlw = Nothing
    If blnEXCEL = True Then xlx.Quit
    Set xlx = Nothing
End Sub

EDIT
I tried the below syntax, and I get an error of

object required

on the line Selection.Font.Bold = True

this is full modified syntax

    With xls
        '.Range("A1:N1").Select
        .Columns("A:N").Select
        Selection.Font.Bold = True
        .Columns("A:N").HorizontalAlignment = xlCenter
        .Columns("A:N").VerticalAlignment = xlBottom
        .Columns("A:N").WrapText = True
        .Columns("A:N").Orientation = 0
        .Columns("A:N").AddIndent = False
        .Columns("A:N").IndentLevel = 0
        .Columns("A:N").ShrinkToFit = False
        .Columns("A:N").ReadingOrder = xlContext
        .Columns("A:N").MergeCells = False
        '.Columns("A:N").Selection.Font.Bold = True
        .Columns("N:N").ColumnWidth = 8.86
        .Columns("I:I").ColumnWidth = 8.86
        .Columns("C:G").Select
        Selection.NumberFormat = "$#,##0"
        .Columns("J:J").Select
        Selection.NumberFormat = "$#,##0"
        .Columns("K:M").Select
        Selection.NumberFormat = "0%"
        .Range("P18").Select
        .Columns("A:A").EntireColumn.AutoFit
        .Columns("B:B").EntireColumn.AutoFit
        .Range("A1").Select
    End With

Answer 1

I am running Excel 2013 and this syntax works for me. First, in the VBE for Access ensure that you have added a reference to

Microsoft Excel 15.0 Object Library

Then to shorten your syntax you can just use the below:

With xls
    .rows("1:1").Font.Bold = True
    .Range("A:N").HorizontalAlignment = xlCenter
    .Range("A:N").VerticalAlignment = xlBottom
    .Range("C:G").NumberFormat = "$#,##0"
    .Range("J:J").NumberFormat = "$#,##0"
    .Range("K:M").NumberFormat = "0%"
    .Range("A:N").WrapText = True
    .Range("N:N").ColumnWidth = 8.86
    .Range("I:I").ColumnWidth = 8.86
    .Range("A:A").ColumnWidth = 9
End With

That should do all the formatting you are after and remove the "fluff" syntax from what appears to be the Macro Recorder. I believe (although I did not test) that the code provided by @June7 would also work if you add the reference to Excel from the VBE.

Answer 2

Tested your code by removing all the recordset stuff just to test the Excel parts. Don't quite get the same error. For me, the 4 lines with Selection reference cause issue.

Added line to select columns A:N and modified the line setting font:
.Columns("A:N").Select
Selection.Font.Bold = True

I Removed the dot (.) from front of Selection on the other 3 lines.

Code ran without error.