MS Access：将子窗体导出到Excel，删除隐藏的列

Question

I have a form with a filtered subform in MS Access with checkboxes controlling the hidden columns. I managed to export the filtered subform to excel, but the hidden columns are kept and shown on the excel file.

How can I only export the visible columns to the excel file?

I am using MS-Access 2007. My code to export so far:

Private Sub btn_export_Click()

On Error GoTo errHandler
Dim qdf As QueryDef
DoCmd.DeleteObject acQuery, "qryTemp"

Set qdf = CurrentDb.CreateQueryDef("qryTemp", Me.Results_Subform.Form.RecordSource)

DoCmd.OutputTo acOutputQuery, "qryTemp", acFormatXLS, "C:\TEST_Export.xls", True
exitHandler:
Exit Sub

errHandler:
If Err.Number = 7874 Then
    Resume Next
Else
    MsgBox Err.Number & " - " & Err.Description
    Resume exitHandler
End If
End Sub

Answer 1

Something like so...

Dim x As Excel.Application
Dim r As Recordset
Dim w As Excel.Worksheet
Dim l As Long
Dim c As New Collection

Set r = Me.Recordset
Set x = New Excel.Application
x.Visible = 1

If x.Workbooks.Count = 0 Then x.Workbooks.Add

Set w = x.Worksheets(1)

For l = 0 To r.Fields.Count - 1
    If Me.Controls(r.Fields(l).Name).ColumnHidden Then
        c.Add l + 1
    End If
    w.Range("a1").Offset(0, l).Value = r.Fields(l).Name
Next l

w.Range("a2").CopyFromRecordset r

For Each i In c
    w.Columns(i).Hidden = True
Next i