从字符串中的第一个单词中删除最后一个字符

Question

I'm using RegEx to search for the string

If RegExp.test(Cel.Value) Then
    Debug.Print Left$(Cel.Value, Len(Cel.Value) - 1)
End If

---

This is my Data

3250A WEST SEM
110055K KEALY RD
804B WEST AMERICA
804 EAST AMERICA

---

Result should be

3250 WEST SEM
110055 KEALY RD
804 WEST AMERICA
804 EAST AMERICA

What is the best way to delete the last character?

Answer 1

You can try this:

^(\d+)[a-zA-Z]*(\s+.*)$

And replace by this:

$1$2

Demo

Answer 2

You can use this regex:

(\d+)(\w{1})(\s.+)

• (\\d+) - capture one or more digits
• (\\w{1}) - capture one letter that you want to remove - if you have examples 123XX SOMEWHERE then to capture XX you would use (\\w+) or (\\w{1,2}) if you think there will be 1, or 2 characters following the number.
• (\\s.+) - capture a space followed by anything

When you want to replace you just want to remove the second match group ( (\\w{1}) ) and join the first and third - hence the $1$3 in the Replace function below:

strReplaced = objRegex.Replace(CStr(varTest), "$1$3")

Example VBA code

Option Explicit

Sub Test()

    Dim objRegex As Object
    Dim varTests As Variant
    Dim varTest As Variant
    Dim strPattern As String
    Dim strReplaced As String

    varTests = Array("3250A WEST SEM", "110055K KEALY RD", "804B WEST AMERICA")
    strPattern = "(\d+)(\w{1})(\s.+)"

    Set objRegex = CreateObject("VBScript.Regexp")
    objRegex.Pattern = strPattern

    For Each varTest In varTests
        strReplaced = objRegex.Replace(CStr(varTest), "$1$3")
        MsgBox strReplaced
    Next varTest

End Sub

Fancy diagram of regex:

Answer 3

RegEx scenario - If you can find <some numbers><single letter><single space> at the beginning of the string, then change the pattern to <single letter><single space> and replace it with a single space.

Option Explicit

Sub stripAlphaSuffix()
    Dim i As Long, regex As Object

    Set regex = CreateObject("VBScript.RegExp")

    With Worksheets("Sheet1")
        For i = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row
            With regex
                .Global = False
                .MultiLine = False
                .IgnoreCase = False
                .Pattern = "^[0-9A-Z ]{3,8}"
            End With
            If regex.Test(.Cells(i, "A").Value2) Then
                regex.Pattern = "[A-Z ]{2}"
                .Cells(i, "A") = regex.Replace(.Cells(i, "A").Value2, Chr(32))
            End If
        Next i
    End With
End Sub

Answer 4

just to throw in a not-RegEx solution:

Dim cel As Range
Dim word As String

For Each cel In Range("A1", Cells(Rows.Count, 1).End(xlUp))
    word = Split(cel, " ")(0)
    cel.Value = Replace(cel.Value, word, Left(word, Len(word) - 1))
Next

Answer 5

As VAL strips non numerics off a alphanumeric string starting with a number then you could try this (which doesn't presume that there is always a character to be replaced)

VAL("3250A") = 3250

Would be more elegant if it didn't need to append the rest of the string :)

Dim StrIn As String
Dim X
StrIn = "3250A WEST SEM"
X = Split(StrIn, Chr(32))
MsgBox Val(StrIn) & Right$(StrIn, Len(StrIn) - Len(X(0)))