错误的用户输入PLS-00201：必须声明标识符“ ISS”

Question

Why do I get this error? If the variable declaration is the same type as the column shouldn't this work. The nursing_unit_id is a varchar2(10). It worked like this for me when the ID was a NUMBER;

Error I get: Error report - ORA-06550: line 13, column 13: PLS-00201: identifier 'ISS' must be declared

SET SERVEROUTPUT ON;
DECLARE
v_unit ADMISSIONS.NURSING_UNIT_ID%TYPE := &v_unit;
v_admissions ADMISSIONS%ROWTYPE;

CURSOR c_admissions IS
  SELECT *
  INTO v_admissions
  FROM ADMISSIONS
  WHERE NURSING_UNIT_ID = v_unit;

BEGIN
  FOR r_admissions IN c_admissions
  LOOP  
    DBMS_OUTPUT.PUT_LINE(r_admissions );
  END LOOP;
END;

Answer 1

If nursing_unit_id is varchar2(10) and you've defined the substitution variable &v_unit as ISS , then you have to enclose the reference to the substitution variable in quotes, to make it a string:

v_unit ADMISSIONS.NURSING_UNIT_ID%TYPE := '&v_unit';

If you run your code in SQL*Plus or SQL Developer with set verify on , you'll see the before and after values for that substitution, which would show it it trying to to do:

v_unit ADMISSIONS.NURSING_UNIT_ID%TYPE := ISS;

instead of what you'd get with it quoted:

v_unit ADMISSIONS.NURSING_UNIT_ID%TYPE := 'ISS';

You will still get other errors; the next one is:

PLS-00306: wrong number or types of arguments in call to 'PUT_LINE'

You've defined v_admissions as a row type, which means it's a record. You can't write a whole record out in one go with dbms_output , you have to refer to each field separately, eg (using your amended code, where `r_admissions is also implicitly of that same row type):

    DBMS_OUTPUT.PUT_LINE(r_admissions.nursing_unit_id);

Having an into clause in the cursor definition isn't useful; it isn't actually populated, so you can remove that clause and the v_admissions variable declaration. You don't really need the v_unit local variable either, you can use the substitution variable directly; and there are various cursor forms you can use, such as:

SET SERVEROUTPUT ON;
BEGIN 
  FOR r_admissions IN (
    SELECT *
    FROM ADMISSIONS
    WHERE NURSING_UNIT_ID = '&v_unit'
  )
  LOOP  
    DBMS_OUTPUT.PUT_LINE(r_admissions.nursing_unit_id);
    -- and anything else you want to do with that row's data
  END LOOP;
END;
/