在Excel VBA中，我需要2个Black-Scholes方法欧式期权定价公式。 使用选择…案例

Question

how's it going. I need Your help again - question is in the topic - here is what I have:

1st formula for call option pricing:

Function CallBS(Spot As Double, Strike As Double, Maturity As Double, Vol As Double, Rf As Double, Dividend As Double) As Double

Dim D1 As Double
Dim D2 As Double

    D1 = (Application.WorksheetFunction.Ln(Spot / Strike) + (Rf - Dividend + Vol * Vol / 2) * Maturity) / Vol * Sqr(Maturity)
    D2 = D1 - Vol * Sqr(Maturity)

    CallBS = Spot * Application.WorksheetFunction.NormSDist(D1) * Exp(-Dividend * Maturity) _
    - Application.WorksheetFunction.NormSDist(D2) * Strike * Exp(-Rf * Maturity)

End Function

This part is working just fine.

2nd formula for put option pricing:

Function PutBS(Spot As Double, Strike As Double, Maturity As Double, Vol As Double, Rf As Double, Dividend As Double) As Double

Dim D1 As Double
Dim D2 As Double

    D1 = (Application.WorksheetFunction.Ln(Spot / Strike) + (Rf - Dividend + Vol * Vol / 2) * Maturity) / Vol * Sqr(Maturity)
    D2 = D1 - Vol * Sqr(Maturity)

    PutBS = Strike * Application.WorksheetFunction.NormSDist(-D2) * Exp(-Rf * Maturity) _
    - Application.WorksheetFunction.NormSDist(-D1) * Spot * Exp(-Dividend * Maturity)

    End Function

This part is working just fine as well.

Now, I need to code another function, with additional argument: option type: "c" or "p" that will be (the formula) universal for both options for call and for put option. Here's how I start:

Function OptnPrcng(OType As String, Spot As Double, Strike As Double, Maturity As Double, Vol As Double, Rf As Double, Dividend As Double) As Double

Dim D1 As Double
Dim D2 As Double
Dim CallBS As Double
Dim PutBS As Double

    D1 = (Application.WorksheetFunction.Ln(Spot / Strike) + (Rf - Dividend + Vol * Vol / 2) * Maturity) / Vol * Sqr(Maturity)
    D2 = D1 - Vol * Sqr(Maturity)

    Select Case OType
        Case "c" Or "C"
            OptnPrcng = Spot * Application.WorksheetFunction.NormSDist(D1) * Exp(-Dividend * Maturity) _
            - Application.WorksheetFunction.NormSDist(D2) * Strike * Exp(-Rf * Maturity)
        Case "p" Or "P"
            OptnPrcng = Strike * Application.WorksheetFunction.NormSDist(-D2) * Exp(-Rf * Maturity) _
            - Application.WorksheetFunction.NormSDist(-D1) * Spot * Exp(-Dividend * Maturity)
        Case Else: MsgBox "Choose |c| for call option or |p| for put option valuation"
    End Select


End Function

But it doesn't work. It gives me an #ARG error.

Answer 1

Try it like this. I really do not know what the formula does, but it gives some result :)

Option Explicit

Function OptnPrcng(OType As String, _
                Spot As Double, _
                Strike As Double, _
                Maturity As Double, _
                Vol As Double, _
                Rf As Double, _
                Dividend As Double) As Double

Dim D1 As Double
Dim D2 As Double
'Dim OType As String
Dim CallBS As Double
Dim PutBS As Double

    D1 = (Application.WorksheetFunction.Ln(Spot / Strike) + (Rf - Dividend + Vol * Vol / 2) * Maturity) / Vol * Sqr(Maturity)
    D2 = D1 - Vol * Sqr(Maturity)

    Select Case LCase(OType)
        Case "c":
            OptnPrcng = Spot * Application.WorksheetFunction.NormSDist(D1) * Exp(-Dividend * Maturity) _
            - Application.WorksheetFunction.NormSDist(D2) * Strike * Exp(-Rf * Maturity)
        Case "p":
            OptnPrcng = Strike * Application.WorksheetFunction.NormSDist(-D2) * Exp(-Rf * Maturity) _
            - Application.WorksheetFunction.NormSDist(-D1) * Spot * Exp(-Dividend * Maturity)
        Case Else: MsgBox "Choose |c| for call option or |p| for put option valuation"
    End Select


End Function

I have changed the Select Case a bit, using LCase .