在VBA MS-Access中嵌套If / Then

Question

I have a table with 7 different milestones, include an ACD and Status for each. I am trying to write code to create an overallstatus, by writing if/then to, beginning at the last milestone, check for a date in the ACD field, and return a corresponding status. If milestone7 has a date, milestone status7 is returned. If there is no date, then it would check if milestone6 acd has a date, and return milestonestatus7 if it does. If it doesnt, it would check milestone5 acd, and if there is a date, return milestone6 status.

This is what I have, and it works fine.

If Not LaunchAndReportingACD Then
    Me.OverallInitiativeStatus = "Complete"
ElseIf Not FinalTargetingACD Then
    Me.OverallInitiativeStatus = LaunchAndReportingStatus
ElseIf Not CommunicationsApprovalACD Then
    Me.OverallInitiativeStatus = FinalTargetingStatus
ElseIf Not CommunicationsDevelopmentACD Then
    Me.OverallInitiativeStatus = CommunicationsApprovalStatus
ElseIf Not VendorContractedACD Then
    Me.OverallInitiativeStatus = CommunicationsDevelopmentStatus
ElseIf Not DesignApprovalACD Then
    Me.OverallInitiativeStatus = VendorContractedStatus
ElseIf Not InitiativeDesignACD Then
    Me.OverallInitiativeStatus = DesignApprovalStatus
Else
    Me.OverallInitiativeStatus = InitiativeDesignStatus
End If

The problem I have is that 2 of the milestones can be Not Applicable, and I need to pass them over, as I dont want to report an overallstatus of Not Applicable. I wrote code individually that works to deal with this; however, I am not able to merge it together completely with my code above.

    If VendorContractedStatus = "Not Applicable" Then
            If Not DesignApprovalACD Then
            Me.OverallInitiativeStatus = CommunicationsDevelopmentStatus
                ElseIf Not InitiativeDesignACD Then
                Me.OverallInitiativeStatus = DesignApprovalStatus
                Else
                Me.OverallInitiativeStatus = InitiativeDesignStatus
                End If
            End If
    If VendorContractedStatus <> "Not Applicable" Then
        If Not VendorContractedACD Then
        Me.OverallInitiativeStatus = CommunicationsDevelopmentStatus
            ElseIf Not DesignApprovalACD Then
            Me.OverallInitiativeStatus = VendorContractedStatus
                ElseIf Not InitiativeDesignACD Then
                Me.OverallInitiativeStatus = DesignApprovalStatus
                Else
                Me.OverallInitiativeStatus = InitiativeDesignStatus
                End If
            End If

Both FinalTarget and VendorContracted have the potential to be not applicable. If either of them are, I want to continue to code to read the milestone before that, and if there is an acd, return the milestone status of the one after (if VendorContracted Status is Not Applicable, I then want to check if DesignApprovalACd has a date, if it does, I want to return CommunicationsDevelopmentStatus as my overallstatus, and if there isnt a date, I want to then check if InitiativeDesignACD has a date, and if so, return DesignApproval Status as the overallstatus, and if not, return Initiative Design Status as the overall status).

The issue I am having is getting it all to flow together. Any suggestions on a better way to do this, or the best way to create if/then/elseif?

I also tried Select Case, doing individual If/Then/End If statements and wasn't able to get it to return the correct results.

Answer 1

After getting my morning coffee (and adding lots of comments to the code), I think I have been able to get my head around what you are trying to achieve.

You should be able to just add the extra conditions to your existing If statement:

If Not LaunchAndReportingACD Then

    'If LaunchAndReportingACD is not Null, then project is Complete
    Me.OverallInitiativeStatus = "Complete"

ElseIf Not FinalTargetingACD Then

    'If FinalTargetingACD is not Null, we are in the LaunchAndReporting phase
    Me.OverallInitiativeStatus = LaunchAndReportingStatus

ElseIf Not CommunicationsApprovalACD Then

    'If CommunicationsApprovalACD is not Null, we are in the FinalTargeting phase,
    ' or the LaunchAndReporting phase (if there is no FinalTargeting phase)
    If FinalTargetingStatus = "Not Applicable" Then
        Me.OverallInitiativeStatus = LaunchAndReportingStatus
    Else
        Me.OverallInitiativeStatus = FinalTargetingStatus
    End If

ElseIf Not CommunicationsDevelopmentACD Then

    'If CommunicationsDevelopmentACD is not Null, we are in the CommunicationsApproval phase
    Me.OverallInitiativeStatus = CommunicationsApprovalStatus

ElseIf Not VendorContractedACD Then

    'If VendorContractedACD is not Null, we are in the CommunicationsDevelopment phase
    Me.OverallInitiativeStatus = CommunicationsDevelopmentStatus

ElseIf Not DesignApprovalACD Then

    'If DesignApprovalACD is not Null, we are in the VendorContracted phase,
    ' or the CommunicationsDevelopment phase (if there is no VendorContracted phase)
    If VendorContractedStatus = "Not Applicable" Then
        Me.OverallInitiativeStatus = CommunicationsDevelopmentStatus
    Else
        Me.OverallInitiativeStatus = VendorContractedStatus
    End If

ElseIf Not InitiativeDesignACD Then

    'If InitiativeDesignACD is not Null, we are in the DesignApproval phase
    Me.OverallInitiativeStatus = DesignApprovalStatus

Else

    'We must be in the InitiativeDesign phase
    Me.OverallInitiativeStatus = InitiativeDesignStatus

End If

---

Note: I did a lot of typing of the variable names, not just copy/pastes, so please check to make sure I didn't introduce any accidental typos.

PS Using code such as Not LaunchAndReportingACD as a way to test for a non-null value (which I assume is what you are doing if LaunchAndReportingACD is a Date ) is confusing. Sure it works, but it would be a lot easier to understand if you said Not IsNull(LaunchAndReportingACD) . Confusing code causes headaches for people who have to maintain your code after you change jobs. (And also confuses people who try to help answer SO questions at 6:00am!)

Answer 2

I wanted to share the updated version thanks to the input on what worked for my form. I took the advise for updating the Not IsNull and modified another line towards the bottom and so far (5 out of my 59 I am testing) it is working perfectly.

If Not IsNull(LaunchAndReportingACD) Then

    'If LaunchAndReportingACD is not Null, then project is Complete
    Me.OverallInitiativeStatus = "Complete"

ElseIf Not IsNull(FinalTargetingACD) Then

    'If FinalTargetingACD is not Null, we are in the LaunchAndReporting phase
    Me.OverallInitiativeStatus = LaunchAndReportingStatus

ElseIf Not IsNull(CommunicationsApprovalACD) Then

    'If CommunicationsApprovalACD is not Null, we are in the FinalTargeting phase,
    ' or the LaunchAndReporting phase (if there is no FinalTargeting phase)
    If FinalTargetingStatus = "Not Applicable" Then
        Me.OverallInitiativeStatus = LaunchAndReportingStatus
    Else
        Me.OverallInitiativeStatus = FinalTargetingStatus
    End If

ElseIf Not IsNull(CommunicationsDevelopmentACD) Then

    'If CommunicationsDevelopmentACD is not Null, we are in the CommunicationsApproval phase
    Me.OverallInitiativeStatus = CommunicationsApprovalStatus

ElseIf Not IsNull(VendorContractedACD) Then

    'If VendorContractedACD is not Null, we are in the CommunicationsDevelopment phase
    Me.OverallInitiativeStatus = CommunicationsDevelopmentStatus

ElseIf Not IsNull(DesignApprovalACD) Then

    'If DesignApprovalACD is not Null, we are in the VendorContracted phase,
    ' or the CommunicationsDevelopment phase (if there is no VendorContracted phase)
    If VendorContractedStatus = "Not Applicable" Then
        Me.OverallInitiativeStatus = CommunicationsDevelopmentStatus
    Else
        Me.OverallInitiativeStatus = VendorContractedStatus
    End If

ElseIf Not IsNull(InitiativeDesignACD) Then

    'If InitiativeDesignACD is not Null, we are in the DesignApproval phase
    Me.OverallInitiativeStatus = DesignApprovalStatus

Else

    'We must be in the InitiativeDesign phase
    Me.OverallInitiativeStatus = InitiativeDesignStatus

End If

This was also another way that the overall status was able to be displayed. A cycle through function was created, as well as a flag, and it loops through to identify the last milestone that has an ECD, and then returns the status of the next milestone. This worked on the continuous form when upon load. I am using the above if/then version (as it is easier for me to manage personally), but also wanted to share this as it was a completely different approach (and I personally enjoy seeing how people do things differently). Thanks again to everyone who helped!

Private Sub Form_Current()
cycleThrough
End Sub

'Private Sub Form_Load()
'
'cycleThrough
'
'End Sub

Function cycleThrough()

Dim lastfield As String
Dim whichfield  As String
Dim whichfield2 As String

Dim flag As Byte

flag = 0

Me.txt_overall.Value = "Hi"


If Not IsNull(txt_LaunchAndReportingACD.Value) Then
whichfield = "LaunchAndReporting"
flag = 1
End If

If Not IsNull(txt_FinalTargetingACD.Value) And flag = 0 Then
whichfield = "FinalTargeting"
flag = 1
End If

If Not IsNull(txt_CommunicationsApprovalACD.Value) And flag = 0 Then
whichfield = "CommunicationsApproval"
flag = 1
End If


If Not IsNull(txt_CommunicationsDevelopmentACD.Value) And flag = 0 Then
whichfield = "CommunicationsDevelopment"
flag = 1
End If


If Not IsNull(txt_VendorContractedACD.Value) And flag = 0 Then
whichfield = "VendorContracted"
flag = 1
End If


If Not IsNull(txt_DesignApprovalACD.Value) And flag = 0 Then
whichfield = "DesignApproval"
flag = 1
End If


If Not IsNull(txt_InitiativeDesignACD.Value) And flag = 0 Then
whichfield = "InitiativeDesign"
flag = 1
End If

Me.txt_overall.Value = whichfield

If whichfield = "LaunchAndReporting" Then
whichfield2 = "Green"
' then green
End If

' And txt_FinalTargetingStatus.Value <> "Not Applicable"

If whichfield = "FinalTargeting" Then
whichfield2 = txt_LaunchAndReportingStatus.Value
End If


If whichfield = "CommunicationsApproval" Then
If txt_LaunchAndReportingStatus.Value <> "Not Applicable" Then whichfield2 = txt_LaunchAndReportingStatus.Value
If txt_FinalTargetingStatus.Value <> "Not Applicable" Then whichfield2 = txt_FinalTargetingStatus.Value
End If

If whichfield = "CommunicationsDevelopment" Then
If txt_LaunchAndReportingStatus.Value <> "Not Applicable" Then whichfield2 = txt_LaunchAndReportingStatus.Value
If txt_FinalTargetingStatus.Value <> "Not Applicable" Then whichfield2 = txt_FinalTargetingStatus.Value
If txt_CommunicationsApprovalStatus.Value <> "Not Applicable" Then whichfield2 = txt_CommunicationsApprovalStatus.Value
End If


If whichfield = "VendorContracted" Then
If txt_LaunchAndReportingStatus.Value <> "Not Applicable" Then whichfield2 = txt_LaunchAndReportingStatus.Value
If txt_FinalTargetingStatus.Value <> "Not Applicable" Then whichfield2 = txt_FinalTargetingStatus.Value
If txt_CommunicationsApprovalStatus.Value <> "Not Applicable" Then whichfield2 = txt_CommunicationsApprovalStatus.Value
If txt_CommunicationsDevelopmentStatus.Value <> "Not Applicable" Then whichfield2 = txt_CommunicationsDevelopmentStatus.Value
End If


If whichfield = "DesignApproval" Then
If txt_LaunchAndReportingStatus.Value <> "Not Applicable" Then whichfield2 = txt_LaunchAndReportingStatus.Value
If txt_FinalTargetingStatus.Value <> "Not Applicable" Then whichfield2 = txt_FinalTargetingStatus.Value
If txt_CommunicationsApprovalStatus.Value <> "Not Applicable" Then whichfield2 = txt_CommunicationsApprovalStatus.Value
If txt_CommunicationsDevelopmentStatus.Value <> "Not Applicable" Then whichfield2 = txt_CommunicationsDevelopmentStatus.Value
If txt_VendorContractedStatus.Value <> "Not Applicable" Then whichfield2 = txt_VendorContractedStatus.Value
End If


If whichfield = "InitiativeDesign" Then
If txt_LaunchAndReportingStatus.Value <> "Not Applicable" Then whichfield2 = txt_LaunchAndReportingStatus.Value
If txt_FinalTargetingStatus.Value <> "Not Applicable" Then whichfield2 = txt_FinalTargetingStatus.Value
If txt_CommunicationsApprovalStatus.Value <> "Not Applicable" Then whichfield2 = txt_CommunicationsApprovalStatus.Value
If txt_CommunicationsDevelopmentStatus.Value <> "Not Applicable" Then whichfield2 = txt_CommunicationsDevelopmentStatus.Value
If txt_VendorContractedStatus.Value <> "Not Applicable" Then whichfield2 = txt_VendorContractedStatus.Value
If txt_DesignApprovalStatus.Value <> "Not Applicable" Then whichfield2 = txt_DesignApprovalStatus.Value
End If



Me.txt_whichStatus.Value = whichfield2



'txt_LaunchAndReportingStatus
'txt_LaunchAndReportingACD
'txt_FinalTargetingStatus
'txt_FinalTargetingACD
'txt_CommunicationsApprovalStatus
'txt_CommunicationsApprovalACD
'txt_CommunicationsDevelopmentStatus
'txt_CommunicationsDevelopmentACD
'txt_VendorContractedStatus
'txt_VendorContractedACD
'txt_DesignApprovalStatus
'txt_DesignApprovalACD
'txt_InitiativeDesignStatus
'txt_InitiativeDesignACD


End Function