如何清除VFD220F显示器上的数据

Question

When I attempt to write to the display its working and shows me the text, but when I delete the text from textbox and press send data it does not change on display, leaving the previous text. If I write another text and send it, it shows me both the old text and new text on the same line.

My question is: How I can delete old text from display and show the new text?
I am using the code below:

Imports System.IO.Ports
Public Class Form1
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        ComboBox1.Items.Clear()
        For Each Nport As String In SerialPort.GetPortNames
            ComboBox1.Items.Add(Nport)
        Next
    End Sub

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Try
            With SerialPort1
                .PortName = ComboBox1.Text
                .BaudRate = 9600
                .DataBits = 8
                .Parity = IO.Ports.Parity.None
                .StopBits = IO.Ports.StopBits.One
                .Handshake = IO.Ports.Handshake.None
            End With
            If Not (SerialPort1.IsOpen = True) Then
                SerialPort1.Open()
            End If
            SerialPort1.DiscardOutBuffer()
            SerialPort1.Write(TextBox1.Text)
            SerialPort1.Close()
            MsgBox("Data sent")
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
End Class

Answer 1

You will need to use the control codes that are provided by the display to clear it. According to the manufacturers documentation some of the available control codes are:

Home ---------------- 0x1 hex 1 Decimal
Backspace --------- 0x8 hex 8 Decimal
Tab ------------------- 0x9 hex 9 Decimal
Line feed ----------- 0xA hex 10 Decimal
Clear Scrn --------- 0xC hex 12 Decimal
Carriage Return - 0xD hex 13 Decimal

Using the above you can do something like this:

Public Class Form1
    Dim displayHome As Byte() = New Byte(0) {&H1}
    Dim displayClear As Byte() = New Byte(0) {&HC}
    Dim displayNewLine As Byte() = New Byte(0) {&HD}
    Dim displayLineFd As Byte() = New Byte(0) {&HA}


    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        ComboBox1.Items.Clear()
        For Each Nport As String In SerialPort.GetPortNames
            ComboBox1.Items.Add(Nport)
        Next
    End Sub

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Try
            With SerialPort1
                .PortName = ComboBox1.Text
                .BaudRate = 9600
                .DataBits = 8
                .Parity = IO.Ports.Parity.None
                .StopBits = IO.Ports.StopBits.One
                .Handshake = IO.Ports.Handshake.None
            End With
            If Not (SerialPort1.IsOpen = True) Then
                SerialPort1.Open()
            End If
            SerialPort1.DiscardOutBuffer()
            'This is one way though the manufacturer doesn't
            'recommend it do to screen flashing.
            SerialPort1.Write(displayClear, 0, 1)
            SerialPort1.Write(TextBox1.Text)
            'Another way would be to go to the home position
            'and make sure you pad enough to cover all of the 
            'previous total.
            SerialPort1.Write(displayHome, 0, 1)
            SerialPort1.Write(TextBox1.Text.PadLeft(20))
            SerialPort1.Close()
            MsgBox("Data sent")
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub
End Class