Bat脚本可查找和替换多个子文件夹中的文件-将.java文件替换为特定文件夹中的.class文件

Question

I am new to windows batch scripting .. please help on this scenario

I have file structures as below ::

dir1 : c:\\workspace\\changeset\\com\\folder

subfolder1

• one.java

subfolder-2

• two.java

dir2 : c:\\workspace\\target\\class\\com\\folder

subfolder1

• one.class

subfolder2

• two.class

Subfolder3

• three.class

Need to find and replace dir1 files in respective subfolders ie one.java and two.java from dir2 files ie one.class and two.class ( need to replace certain .java files with .class files from specific folder )

much appreciated for your help.

Thanks Arjun

Answer 1

for /f "delims=" %%a in ('dir /b /a-d "c:\workspace\changeset\com\folder\*.java"') do (
 if exist "c:\workspace\target\class\com\folder\%%~na.class" (
  echo copy "c:\workspace\target\class\com\folder\%%~na.class" "c:\workspace\changeset\com\folder\%%a")
)

The required COPY commands are merely ECHO ed for testing purposes. After you've verified that the commands are correct , change ECHO COPY to COPY to actually copy the files. Append >nul to suppress report messages (eg. 1 file copied )

Note that execution directly from the prompt and as lines with a batch file are different. The metavariable (loop-control variable) %%x must be referenced as %%x for a batch line and %x if executed from the command prompt. Since it makes little sense to repeatedly execute a line containing a for from the prompt (it's easier to create a batch file), I post the batch-file version. User's responsibility to adjust for direct-from-prompt if desired.

Read each filename in /b basic form /ad without directories and assign the filename+extension to %%a .

If a file in the other directory called thenamepartofthefile .class exists, then copy that file to the first directory.

---

Please post the entire problem to be solved. The approach can change radically, as in this case.

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
SET "sourcedir1=U:\sourcedir\changeset"
SET "sourcedir2=U:\sourcedir\target"
FOR /f "delims=" %%a IN (
 'dir /b /s /a-d "%sourcedir1%\*.java" '
 ) DO (
 SET "javadir=%%~dpa"
 SET "classfile=!javadir:%sourcedir1%=%sourcedir2%!%%~na.class"
 IF EXIST !classfile! ECHO COPY "!classfile!" "%%a"
)

GOTO :EOF

You would need to change the settings of sourcedir1 and sourcedir2 to suit your circumstances.

Essentially, the same approach and the same comments re messages. The difference is that this procedure uses files and subdirectories in the dir list and substitutes the first part of the directoryname in deriving the expected name of the .class file.