VBA Excel循环基于C列中的值删除范围

Question

I am trying to delete a specific range based on whether or not column "C" meets specific criteria.

Currently I have the following:

If Range("C69") = "All values USD Millions." Then
    Range("C69 : H69").Delete shift:=xlUp
Else Range("A3").Select
End If

I want to turn this into a loop that will search cells "C1" through "C100" for the words "All values USD Millions." and delete the corresponding C though H range. For example, if it found the value in "C15", it would delete Range("C15:H15").

Unfortunately, I am still learning and all the loops I try create an error.

Answer 1

You can use the filtering capability of Excel:

With Sheet1.Range("C1:H100")
    .AutoFilter 1, "All values USD Millions."
    .Offset(1).Delete
    .AutoFilter
End With

However if you want to do a "classic" iteration and delete while iterating on the rows, remember always that in these cases you should iterate "backward" :

Dim i as long
For i = Range("C999999").End(xlUp).Row to 1 Step -1
    If Cells(i, "C").Value2 = "All values USD Millions." Then Rows(i).Delete
Next

Answer 2

Another fast way, without looping throughout the rows one by one, is using the Find function:

Option Explicit

Sub UseFindFunc()

Dim FindRng         As Range
Dim Rng             As Range
Dim LastRow         As Long
Dim TexttoFind      As String

TexttoFind = "All values USD Millions." ' <-- try to use variable, easy to modify later

With Sheet1
    LastRow = .Cells(.Rows.Count, "C").End(xlUp).Row '<-- get last row with data in Column C
    Set Rng = .Range("C1:H" & LastRow)

    Set FindRng = Rng.Find(What:=TexttoFind, LookIn:=xlValues, LookAt:=xlWhole)
    While Not FindRng Is Nothing '<-- find was successful
        FindRng.Resize(, 5).Delete xlShiftUp '<-- delete column "C:H" in found row
        Set FindRng = Rng.Find(What:=TexttoFind, LookIn:=xlValues, LookAt:=xlWhole)
    Wend
End With

End Sub

Answer 3

Try using:

For i=1 to 100
    If Cells (i, 3) = "All values USD Millions." Then

        Rows (i).Delete

    EndIf
Next

Answer 4

If you don't want to delete cells from columns A and B, this works for me:

Sub test()
Dim i As Integer
For i = 1 To 100
    If Range("C" & i) = "All values USD Millions." Then
        Range("C" & i & ":H" & i).Delete
    Else
        Range("A3").Select
    End If
Next
End Sub

Answer 5

If your data is not as static you could do the script till your last row or set i = 1 to 100 to stop at row 100

    Sub test()
    Dim lRow As Long

     lRow = WorksheetFunction.Max(Range("C65536").End(xlUp).Row, 
     Range("D65536").End(xlUp).Row, Range("E65536").End(xlUp).Row)

    With ActiveSheet
    For i = lRow To 2 Step -1
    If .Cells(i, "C").Value = "All values USD Millions." Then
      Range("C" & i & ":H" & i).ClearContents
    End If
   Next i
   End With


   End Sub