禁用/启用复制粘贴

Question

I have these two codes:

The first is a macro to disable copy-paste:

Sub Desable_Copy()

    Dim oCtrl As Office.CommandBarControl

    For Each oCtrl In Application.CommandBars.FindControls(ID:=21)
        oCtrl.Enabled = False
    Next oCtrl

    For Each oCtrl In Application.CommandBars.FindControls(ID:=19)
        oCtrl.Enabled = False
    Next oCtrl

    Application.CellDragAndDrop = False
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    With Application
        .CellDragAndDrop = False
        .CutCopyMode = False 'Clear clipboard
    End With
End Sub

The second is a macro to enable copy-paste:

Sub Enable_Copy()

    Dim oCtrl As Office.CommandBarControl

    For Each oCtrl In Application.CommandBars.FindControls(ID:=21)
        oCtrl.Enabled = True
    Next oCtrl

    For Each oCtrl In Application.CommandBars.FindControls(ID:=19)
        oCtrl.Enabled = True
    Next oCtrl

    Application.CellDragAndDrop = True
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    With Application
        .CellDragAndDrop = True
        .CutCopyMode = True 'Clear clipboard
    End With
End Sub

When I execute the code I have an error message:

Ambiguous Name Detected

Answer 1

Excel's Copy/Paste capabilities are set for the Excel application. If you disable them for one workbook they are disabled for all. If you have several workbooks open at the same time the management becomes quite a chore - if you are an expert programmer which perhaps you are not. Consider alternatives, such as Application.Undo which can be made to run on the Worksheet_Change event. The following code will undo any Paste operation on the worksheet.

Private Sub Worksheet_Change(ByVal Target As Range)
    ' 18 Apr 2017

    Dim UndoList As String

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    On Error GoTo ErrExit
    UndoList = Application.CommandBars("Standard").Controls("&Undo").List(1)
    If Left(UndoList, 5) = "Paste" Or UndoList = "Auto Fill" Then
        MsgBox "Please don't paste values on this sheet." & vbCr & _
               "The action will be reversed.", vbInformation, _
               "Paste is not permitted"
        With Application
            .Undo
            .CutCopyMode = False
        End With
        Target.Select
    End If

ErrExit:
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

This code was adapted from code published here (edit ML: original link is broken, I found this one as a substitute /edit). The view taken there is not to prevent paste operations but to prevent paste operations from messing up sheet formatting. It is a very interesting piece, well explained and easy to implement.

Answer 2

You got 2 private Subs with the same name.

For example, you can change the second one:

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)

to

Private Sub Workbook_SheetSelectionChangeEnable(ByVal Sh As Object, ByVal Target As Range)