Excel-VBA：如何检查每个单元格的最后一个字符是否>（超级符号）

Question

How do I check in VBA-Excel whether the last character of every single cell of my sheet is a > (superior sign).

Below is what I've been doing so far.

Dim c As Range

For Each c In Range("C1", Range(">" & Rows.Count).End(xlUp))
    If Not IsNumeric(Mid(c, 3, 1)) Then
        MsgBox ("Found !!!")
    End If
    Exit For
Next c

Answer 1

You can use right function to get last character and check if it equals chr(62) which is >

You can modify you code in a way below:

Right(ActiveCell.Value, 1) = Chr(62)

It will return TRUE if last character is >

Answer 2

You can use the Like operator with the wild-card * as a prefix.

Inside your For loop, to check if a cell has a > at the end, use:

Dim C As Range

With Worksheets("Sheet3") ' <-- modify "Sheet3" to your sheet's name
    ' loop through column C, from C1 until last cell with data in Column C (including blank cells in the middle)
    For Each C In Range("C1:C" & .Cells(.Rows.Count, "C").End(xlUp).Row)
        If C.Value Like "*>" Then '<-- if the end of the cell is ">"
            MsgBox "Found !!! at Cell " & C.Address
        End If
    Next C
End With

Answer 3

First you use the active sheet. Then you try to find the last row in column "C". Once you find it, you start looping over the range from C1 to C&lastRow. There, if you find the sign ">" on the right you print "found" and the row number in the immediate window. Then you exit the sub.

Here is the code:

Public Sub TestMe()

    Dim c           As Range
    Dim lastRow     As Long

    With ActiveSheet
        lastRow = .Cells(.Rows.Count, "C").End(xlUp).Row

        For Each c In .Range(.Cells(1, 3), .Cells(lastRow, 3))
            If Right(c, 1) = ">" Then
                Debug.Print "FOUND"
                Debug.Print c.Row
            Exit For
            End If


        Next c

    End With

End Sub

Answer 4

As I read your question title, you said that you want to check if the right most character in each cell in column C is ">". Right?

The I don't understand why you are using Exit For once a ">" is found any cell though it is used at wrong place as it will be triggered after first loop.

If you want to achieve what your question title says, try this...

The following code will check each cell in column C and return a "Found!" if the last character was a ">" or will return "Not Found!".

Sub CheckTheLastCharacterInString()
    Dim lr As Long
    lr = Cells(Rows.Count, "C").End(xlUp).Row
    Range("D1:D" & lr).Value = Evaluate("IF(RIGHT(C1:C" & lr & ",1)="">"",""Found!"",""Not Found!"")")
End Sub