Groovy每个关闭错误

Question

I know Java but completely new to Groovy. I have got some legacy code in Groovy to work on.

I have below method in Groovy:

def mapMyNotificationsByFruits(prefs,fruits) {
    def map = [:]
    prefs.each { MainNotification cn ->
        cn.fruits.each {
            MyNotification an ->
            def ex = map[(an.fruitId)]
            if (!ex) ex = []
            ex.add(an)
            map[(an.fruitId)] = ex
        }
    }
    log.info("map is: $map")
    return map
}

Above method gets called from another method as below:

def notificationPrefsByFruit = mapMyNotificationsByFruits(prefs, fruits)

When I debug on first line in mapMyNotificationsByFruits method, I get prefs as

MainNotification [someId=ABC123, email=abc@gmail.com, fruits=[{fruitId=XYZ123, someField=0}]]

On running this code, I get following error:

groovy.lang.MissingMethodException: No signature of method: com.somepackage.SomeClass$_mapMyNotificationsByFruits_closure5$_closure10.doCall() is applicable for argument types: (groovy.json.internal.LazyMap) values: [[{fruitId=XYZ123, someField=0}]]

What is wrong here ?

What does these line do:

MyNotification an ->
        def ex = map[(an.fruitId)]
        if (!ex) ex = []
        ex.add(an)
        map[(an.fruitId)] = ex

Is it a casting issue?

Replacing above lines with below code resolves the issue:

MyNotification an = it
def ex = map[(an.fruitId)]
if (!ex) ex = []
ex.add(an)
map[(an.fruitId)] = ex

But I am not sure if both code blocks are same and I am fixing it correctly.

Thanks in advance!

Answer 1

What does the Algorithm do?
Given list of MainNotification instances it is grouping the MyNotification instances by fruitId .

Given :

[   
    [
        someId: "ABC123",
        email: "abc@gmail.com",
        fruits: [
            [fruitId : "XYZ123", someField: 0],
            [fruitId : "XYZ124", someField: 6],
        ]
    ],

    [
        someId: "XYSK",
        email: "yax@gmail.com",
        fruits: [
            [fruitId : "XYZ123", someField: 5],
            [fruitId : "XYZ124", someField: 2],
            [fruitId : "XYZ144", someField: 9],
        ]
    ]
]

Expected Output:

[
    XYZ123 : [
            [fruitId : "XYZ123", someField: 0],
            [fruitId : "XYZ123", someField: 5]
         ],
    XYZ124 : [
            [fruitId : "XYZ124", someField: 6],
            [fruitId : "XYZ124", someField: 2]
         ],
    XYZ144 : [ 
            [fruitId : "XYZ144", someField: 9]
         ]
]

Corrections:

• fruits variable is never used on the method so please remove it.
• The method is calling each method on the prefs variable so it is expecting prefs to be List<MainNotification> instead of MainNotification .
• On the nested closure this code: cn.fruits.each is expecting each fruit to be instance of MyNotification ( this is the main fix to your issue btw ).

You did not post the source code for MainNotification and MyNotification so per the input data you gave on your question I modeled them like this:

class MainNotification{
    String someId;
    String email;
    List<MyNotification> fruits;
}

class MyNotification{
    String fruitId;
    int someField;
}

With the corrections and assumptions here is the working code:

def mapMyNotificationsByFruits(prefs,fruits) {
    def map = [:]
    prefs.each { MainNotification cn ->
        cn.fruits.each { MyNotification an ->
            def ex = map[(an.fruitId)]
            if (!ex) ex = []
            ex.add(an)
            map[(an.fruitId)] = ex
        }
    }
    println ("map is: $map")
    return map
}

MainNotification mainNotification = new MainNotification(someId: "ABC123",
        email: "abc@gmail.com",
        fruits: [new MyNotification(fruitId : "XYZ123", someField: 0)]
);

MyNotification fruits = null; //never used on the method

List<MainNotification>  prefs = [mainNotification];

def notificationPrefsByFruit = mapMyNotificationsByFruits(prefs, fruits)